Completed To do's search

Question

Since iCal doesn't have smart folders. How can I search for completed to do's for like the last month. Also, when I set a to do date, but complete the to do maybe 2 days later, how do I know what day I completed it. Or does it default to the date I set to be completed by?

Answer 1

Hi Rolland,
iCal stores the date of completion, but I don't think it can display it.
You can access the completion dates. For example this Applescript loops through the todos of one calendar and displays the completion date of completed todos of that calendar.
To try this, copy the blue text into a Script Editoer window (Applications > Applescript > Script Editor) and press RUN then follow the prompts.
tell application "iCal"
-- Convoluted way to get the right iCal calendar.
set sourceCal to first calendar whose title is (item 1 of (choose from list (title of (every calendar) as list) with prompt "Choose calendar to delete duplicates"))
-- Get Titles and Completion Dates of Todos.
set {myTitles, myEnds} to {summary, completion date} of todos of sourceCal
end tell
-- Repeat with myTodo being a number from 1 to count of Todos
repeat with myItem from 1 to (length of myTitles)
-- Check if the todo has a completion date
if (item myItem of myEnds) is not missing value then
-- Set a variable to the completion date of the todo
-- in short date form.
set myDate to short date string of (item myItem of myEnds)
-- Get iCal to make the dialog window
tell application "iCal"
-- Display text saying "TODO TITLE was completed: XX/XX/XX"
display dialog "'" & (item myItem of myTitles) & "' was completed: " & myDate
end tell
end if
end repeat
You could write a script to list the todos completed in the last month (or completed on tuesdays, or many other restrictions).
Best wishes
John M