Confirmation of messages in BPS - possible in FOX?

Question

Hi Marc / Gerd,
We have done confirmation in ABAP Exits before but wanted to check if there are any options to request confirmation message Y/N in FOX formula.  The only solution I have though of so far was to do a EXIT function and the FOX formula and put it in a sequence but cannot guareentee 100% that we can skip to FOX if the confirmation is negative. 
Any other tips and hints would be appreciated
Thanks,
Mary

Answer 1

Mary,
here's who to do it. Create an exit function. In the init module call the popup for confirmation and store the result in a global variable. In the exit module evaluate the result and if the answer was "yes" use CALL FUNCTION 'UPC_FUNCEXEC' to execute the FOX planning function (or any other type of function). Now since the called function can change the data, you have to read the updated data from the buffer.
Here's the coding (without the popup logic) using two parameters in the BPS parameter group to pass the function and parameter group that should be called:
FUNCTION /sapcsem/z_sem_bps_funct_exec.
*"*"Local interface:
*"  IMPORTING
*"     VALUE(I_AREA) TYPE  UPC_Y_AREA
*"     VALUE(I_PLEVEL) TYPE  UPC_Y_PLEVEL
*"     VALUE(I_METHOD) TYPE  UPC_Y_METHOD
*"     VALUE(I_PARAM) TYPE  UPC_Y_PARAM
*"     VALUE(I_PACKAGE) TYPE  UPC_Y_PACKAGE
*"     REFERENCE(IT_EXITP) TYPE  UPF_YT_EXITP
*"     REFERENCE(ITO_CHASEL) TYPE  UPC_YTO_CHASEL
*"     REFERENCE(ITO_CHA) TYPE  UPC_YTO_CHA
*"     REFERENCE(ITO_KYF) TYPE  UPC_YTO_KYF
*"  EXPORTING
*"     REFERENCE(ET_MESG) TYPE  UPC_YT_MESG
*"  CHANGING
*"     REFERENCE(XTH_DATA) TYPE  HASHED TABLE
  DATA:
    ls_exitp        TYPE upf_ys_exitp,
    l_exit_method   TYPE upc_y_method,
    l_exit_param    TYPE upc_y_param,
    ls_mesg         TYPE upc_ys_mesg,
    ls_log          TYPE upc_ys_log,
    lt_log          TYPE upc_yt_log,
    l_error         TYPE boole_d.
  DATA:
    lr_plarat TYPE REF TO cl_sem_planarea_attributes,
    lr_chalev TYPE REF TO if_sem_chalev,
    lr_kyflev TYPE REF TO if_sem_kyflev,
    lr_chasel TYPE REF TO if_sem_chasel,
    lr_data   TYPE REF TO if_sem_data.
* Get exit parameter
  LOOP AT it_exitp INTO ls_exitp.
    CASE ls_exitp-parnm.
      WHEN 'METHOD'.          " Planning function
        l_exit_method = ls_exitp-chavl.
      WHEN 'PARAM'.           " Parameter group
        l_exit_param  = ls_exitp-chavl.
    ENDCASE.
  ENDLOOP.
  MESSAGE i001 INTO g_dummy WITH
    'Executing planning function' l_exit_method
    'and parameter group'         l_exit_param.
  log_append.
* Call BPS planning function
  CALL FUNCTION 'UPC_FUNCEXEC'
    EXPORTING
      i_area          = i_area
      i_plevel        = i_plevel
      i_package       = i_package
      i_method        = l_exit_method
      i_param         = l_exit_param
    IMPORTING
      et_log          = lt_log
      e_error_occured = l_error.
* Return log entries
  LOOP AT lt_log INTO ls_log.
    ls_mesg = ls_log-s_mesg.
    IF ls_mesg-msgid <> 'UPC' OR ls_mesg-msgno <> '224'.
      APPEND ls_mesg TO et_mesg.
    ENDIF.
  ENDLOOP.
* Now get data that potentially has been changed by the BPS planning function
  IF l_error IS INITIAL.
    lr_plarat = cl_sem_planarea_attributes=>get_instance( i_area ).
    lr_chalev = lr_plarat->r_factory->create_chalev( ito_cha ).
    lr_kyflev = lr_plarat->r_factory->create_kyflev( ito_kyf ).
    lr_chasel = lr_plarat->r_factory->create_chasel( ito_chasel ).
    lr_data  ?= lr_plarat->r_factory->create_data(
                                      ir_chalev = lr_chalev
                                      ir_chasel = lr_chasel
                                      ir_kyflev = lr_kyflev ).
    CALL METHOD lr_data->read
      EXPORTING
        i_enqmode = 'E'
      EXCEPTIONS
        OTHERS    = 1.
    CALL METHOD lr_data->get_data
      EXPORTING
        ir_chasel = lr_chasel
      IMPORTING
        eth_data  = xth_data.
  ENDIF.
ENDFUNCTION.
Regards
Marc
SAP NetWeaver RIG