Copying path into variable

Question

At least I think that's what I mean... Another very basic question!
My script is to set up a folder structure for jobs.
Basically I have:
set the_user to short user name of (system info)
(for which thanks, Michael)
then a lot of
make folder at folder "3 Artwork" of folder job_folder of folder "Desktop" of folder the_user of folder "Users" of startup disk with properties {name:"AW PDFs for Client"}
type instructions
I'd like to be able to tidy this up like:
set my_desktop to folder "Desktop" of folder the_user of folder "Users" of startup disk
- but this and variations on it don't seem to work. I have a hazy feeling the words 'a reference to' may need to appear somewhere, but haven't been able to make that work either!
I'm afraid this forum is making me lazy, but I'm up against time constraints here!

Answer 1

Hello Emma Glaisher,
Usually, the essential information you need to manipulate file/folder is its path information, e.g.
"Production:A:Argos:001122-Leaflet:"
All other things can be delived from it.
cf. pp.190-194
AppleScriptLanguageGuide.pdf
Note that 'folder A of folder B of folder C of disk D' sort of reference is 'Finder's reference form (Finder's object specfier) according to its AppleScript's object model and actually only used in 'Finder'. You don't have to bother with its lengthy form. Normally all you need is path string (or alias object associated to it).
* AppleScript's 'alias' is NOT Finder's 'alias file'. It's AppleScript's object of «class alis» that holds an 'alias record' for file system object. (Finder's 'alias file' is a file that contains an 'alias record' for its target object)
Also note that 'path string' may be plain string («class TEXT») or Unicode text («class utxt») in AppleScript terms. In some cases, you should be aware of the diffrence between them. (Possibly recent OSX's Finder may not coerce its item (folder/file/disk, etc) reference to plain string, but only to Unicode text. Just a guess)
Here's some sample code for you.
(Tested with OS9.1, not with OSX, sorry. I don't use OSX)
Hope it helps you to clear things up.
H
-- SCRIPT
(* 1. Path string *)
set node0 to "Production"
set node1 to "A"
set node2 to "Argos"
set node3 to "001122-Leaflet"
set fp to node0 & ":" & node1 & ":" & node2 & ":" & node3 & ":"
set fp to "Production:A:Argos:001122-Leaflet:" -- path string (= AppleScript's string object)
(* 2. Some basic forms for referring to file system object *)
set f_alias to fp as alias -- = AppleScript's alias object (# node fp must actually exist)
set f_fss to file fp as file specification -- = AppleScript's file specification object
-- return {fp, f_fss, f_alias} -- # uncomment this line to see what they are.
(* 3. Several ways to make new folder by Finder *)
-- (a) using Finder's item object
tell application "Finder"
-- (item fp) = Finder's item object
make new folder at (item fp) with properties {name:"3 Artwork"}
end tell
-- (b) using Finder's folder object, virtually identical to (a)
tell application "Finder"
-- (folder fp) = Finder's folder object
make new folder at (folder fp) with properties {name:"3 Artwork"}
end tell
-- (c) using AppleScript's alias
tell application "Finder"
-- (f_alias) = alias object given above
make new folder at (f_alias) with properties {name:"3 Artwork"}
end tell
-- (d) using AppleScript's file specification
tell application "Finder"
-- (f_fss) = file specification object given above
make new folder at (f_fss) with properties {name:"3 Artwork"}
end tell
-- END OF SCRIPT
  Mac OS 9.1.x