Custom Ribbon Menu in MS Project Professional 2013

Question

Hi all,
I want to create a custom ribbon menu in MS Project Professional 2013 but I am not sure how to save it as a template and apply it enterprise wide.
Or is it something that needs to be packaged?
Thanks!
SJ

Answer 1

Apologies for the delay. To get this working in VBA you need to construct a Ribbon XML format version of the menu as you want it. I've copied an example below, but there is a
Microsoft page with information on how the schema works. Key lessons I've learnt are that:
button id and group id values - doesn't seem to matter what they are, but they must be unique
imageMSOs - for the gallery of images that you can choose from is published by Microsoft
here. I found various pages that described how to add custom images to the ribbon in Excel, but I never managed to get them to work for me, so just stuck with the images in this file.
Don't expect any meaningful error messages if you make mistakes in the XML - it just won't appear. I found putting the value of the string into an XML editor was useful for highlighting some errors.
The ribbon menu is actually applied to projects rather than the application, so if you don't have any projects open, then the ribbon menu won't appear.
Here's my example, which adds a "New Menu" tab to the ribbon, with a couple of buttons to launch macros. This can just be added to a new module in your global file.
'===========================================================================
' Developed by A Simpson, 27 November 2013
'===========================================================================
Public Sub evst_AddCustomRibbon()
Dim customUiXml As String
Dim pj As Project
customUiXml = "<mso:customUI xmlns:mso=""http://schemas.microsoft.com/office/2009/07/customui"" loadImage=""LoadImage"" >" _
& "<mso:ribbon><mso:tabs><mso:tab id=""evst"" label=""New Menu"">"
customUiXml = customUiXml _
& "<mso:group id=""group0"" label=""Reporting"">" _
& "<mso:button id=""button0-1"" label=""Task Usage+"" size=""large"" " _
& "imageMso=""TaskUsageViewGallery"" onAction=""Macro1"" " _
& "supertip=""Gives a report of the projected expenditure on the project.""/>" _
& "<mso:button id=""button0-2"" label=""Resource Usage+"" size=""large"" " _
& "imageMso=""ResourceAllViewsGallery"" onAction=""Macro2"" " _
& "supertip=""Gives the projected headcount of the project in FTE values."" />" _
& "</mso:group>"
customUiXml = customUiXml _
& "<mso:group id=""group1"" label=""Eversight QA"">" _
& "<mso:button id=""button1-1"" label=""DCMA 14 point Analysis"" size=""normal"" " _
& "imageMso=""GroupResolveConflictsAndErrors"" onAction=""Macro3"" " & "supertip=""Executes the DCMA 14 point assessment of the current schedule.""/>" _
& "<mso:button id=""button1-2"" label=""Eversight Advanced QA"" size=""normal"" " _
& "imageMso=""PwaProjectProgressUpdate"" onAction=""Macro4"" " & "supertip=""Executes the Eversight QA Advanced checks, as configured in Eversight > Options."" />" _
& "<mso:button id=""button1-3"" label=""Eversight Basic QA"" size=""normal"" " _
& "imageMso=""PwaProjectProgressUpdate"" onAction=""Macro5"" " & "supertip=""Executes the Eversight QA Basic checks, as configured in Eversight > Options.""/>" _
& "</mso:group>"
customUiXml = customUiXml _
& "</mso:tab></mso:tabs></mso:ribbon></mso:customUI>"
For Each pj In Application.Projects
pj.SetCustomUI (customUiXml)
Next pj
End Sub
You'll also need an event which executes this macro. The following code goes in the "Microsoft Project Objects > ThisProject (Global.MPT)" module within the global file:
Option Explicit
Public WithEvents MSPApp As Application
Private Sub MSPApp_WindowActivate(ByVal activatedWindow As Window)
evst_AddCustomRibbon
End Sub
I hope that gets you started,
Thanks,
Andrew
Andrew Simpson
Founder – Eversight Ltd
E: [email protected]
W: www.eversight.co.uk
Download Eversight for MS Project — a free add-on which helps users build high quality schedules with MS project.