DBSM_AQ SORT_LIST problem, timestamp is ignored.

Question

Hello,
I am using dbms_aq to enqueue and dequeue data. The sort list on the queue table is 'PRIORITY,ENQ_TIME'
I am seeing that the ENQ_TIME is ignored when two records are enqueued in the same second but with different timestamp. I am not using any dequeue_condition
            PRIORITY    ENQUEUE_TIME                         DEQUEUE_TIME
Record1     1003        12/11/2014 1:43:35.084026000 PM      12/11/2014 1:43:36.656810000 PM
Record2     1003        12/11/2014 1:43:35.801906000 PM      12/11/2014 1:43:36.509805000 PM  <--- Dequeued first
I have checked the documentation, but could not find any information that this will be ignored. This is randomly happening some times.
Here is my code, And thanks in advance,
BEGIN
   DBMS_AQADM.CREATE_QUEUE_TABLE (queue_table          => 'mpi_aqadm.qtab_message',
                                  queue_payload_type   => 'mpi_aqadm.typ_message',
                                  sort_list            => 'PRIORITY,ENQ_TIME',
                                  COMMENT              => 'Queue table for message Sync');
END;
BEGIN
   DBMS_AQADM.CREATE_QUEUE (queue_name    => 'mpi_aqadm.aq_message',
                            queue_table   => 'mpi_aqadm.qtab_message',
                            max_retries   => 0,
                            retry_delay   => 60,
                            COMMENT       => 'Advanced queue for message Sync');
END;
BEGIN
   DBMS_AQADM.START_QUEUE (queue_name => 'mpi_aqadm.aq_message');
END;
--Enqueue Code
PROCEDURE prcenqueue (pinPriorityKey IN NUMBER, pinmessagekey IN NUMBER)
IS
   lvModuleId     CONSTANT VARCHAR2 (20) := 'PDR 1.01';
   ltypPdrSync             mpi_aqadm.typ_message;
   ltypEnqueueOptions      DBMS_AQ.ENQUEUE_OPTIONS_T;
   ltypMessageProperties   DBMS_AQ.MESSAGE_PROPERTIES_T;
   lrMsgID                 RAW (16);
   lvYrMonthDay            NUMBER (6) := TO_NUMBER (TO_CHAR (SYSDATE, 'YYMMDD'));
BEGIN
   ltypPdrSync := mpi_aqadm.typ_message(pinmessagekey);
   ltypMessageProperties.priority := lvYrMonthDay || pinPriorityKey;
   DBMS_AQ.ENQUEUE (queue_name           => 'mpi_aqadm.aq_message',
                    enqueue_options      => ltypEnqueueOptions,
                    message_properties   => ltypMessageProperties,
                    payload              => ltypPdrSync,
                    msgid                => lrMsgID);
END;
-- Dequeue Data
/* Formatted on 3/2/2015 5:49:13 PM (QP5 v5.252.13127.32847) */
PROCEDURE prcdequeue
IS
   dopt            DBMS_AQ.DEQUEUE_OPTIONS_T;
   mprop           DBMS_AQ.MESSAGE_PROPERTIES_T;
   msg             RAW (16);
   no_message      EXCEPTION;
   fetch_timeout   EXCEPTION;
   PRAGMA EXCEPTION_INIT (NO_MESSAGE, -25254);
   PRAGMA EXCEPTION_INIT (FETCH_TIMEOUT, -25228);
   get_data        mpi_aqadm.typ_message;
BEGIN
   dopt.WAIT := DBMS_AQ.NO_WAIT;
   dopt.navigation := DBMS_AQ.FIRST_MESSAGE;
   dopt.dequeue_mode := DBMS_AQ.REMOVE;
   DBMS_AQ.DEQUEUE (queue_name           => 'MPI_AQADM.aq_message',
                    dequeue_options      => dopt,
                    message_properties   => mprop,
                    payload              => get_data,
                    msgid                => msg);
   prcprocessmessage (get_data.pinmessagekey);
END;
Thanks,
G.

Answer 1

I also see this in documentation
If several messages are enqueued in the same second, then they all have the same enq_time. In this case the order in which messages are dequeued depends on step_no, a variable that is monotonically increasing for each message that has the same enq_time. There is no situation when both enq_timeand step_no are the same for two messages enqueued in the same session.
Do you think there is an issue around this?