Different Style on Last Paragraph?

Question

I have a style that sets a paragraph rule below each paragraph to act as a divider. I need to apply this in many paces, however I would like the last paragraph in each section to have no rule. Is this possible?
I don't want to have to apply a different style to the last paragraph in each section because the text is regularly updated...

Answer 1

Which is still not an automated solution...it would need to be run after every edit.
Right it wouldn't be completely automatic, but you wouldn't have to run it after every edit—just after the final edit.
It isn't clear if the text is flowing between frames, the OP's #6 makes it sound like it's 1 frame. If it is flowing you can check if a paragraph's last line is the last line of a frame, so it still could be done with flowing text.
So this AppleScript gets every story in the document and checks the story's paragraphs. If the paragraph has a style sheet applied with rule below on and it's the last paragraph, the rule below gets turned off, otherwise the rule gets turned on.
tell application "Adobe InDesign CC 2014"
    tell active document
        --get the document stories
        set s to every story
        repeat with x in s
            --check each paragraph
            set ps to object reference of every paragraph of x
            repeat with i from 1 to count of ps
                set p to item i of ps
                --if it's the last paragraph and the p style has a rule below set it to off, else make sure it is on
                if i is equal to (count of ps) then
                    if rule below of applied paragraph style of p then set rule below of p to false
                else
                    if rule below of applied paragraph style of p then set rule below of p to true
                end if
            end repeat
        end repeat
    end tell
end tell