Double-Sided Name Badges ...

Question

How do I import a multi-page PDF document in InDesign and then Duplicate each page in order to output double-sided SAME image ?

Answer 1

There's a sample script that comes with ID, that places multi-page PDFs. It would be fairly easy to adjust the example to place the pages twice. So the ApplScript version would be (run the script and choose the PDF with pages to place):
===================================
set myPDF to choose file "Select a PDF file to place"
tell application "Adobe InDesign CS6"
    set myDocument to make document
    my myPlacePDF(myDocument, page 1 of myDocument, myPDF)
end tell
--places each page of the pdf on a new page and duplicates
on myPlacePDF(myDocument, myPage, myPDF)
    tell application "Adobe InDesign CS6"
        set myDone to false
        set PDF crop of PDF place preferences to crop media
        --a counter for pdf page count
        set myCounter to 1
        repeat until myDone is true
            tell myDocument
                if myCounter > 1 then
                    set myPage to make page at after myPage
                end if
            end tell
            set page number of PDF place preferences to myCounter
            --place the pdf page
            tell myPage
                set myPDFPage to place myPDF
                set myPDFPage to item 1 of myPDFPage
            end tell
            --if it's page 1 adjust the document to the PDF page dimensions
            if myCounter = 1 then
                set myFirstPage to page number of PDF attributes of myPDFPage
                set {a, b, c, d} to geometric bounds of parent of myPDFPage
                set properties of document preferences of myDocument to {facing pages:false, page width:d, page height:c}
                --reset the first PDF position
                set geometric bounds of parent of myPDFPage to {a, b, c, d}
                set geometric bounds of myPDFPage to {a, b, c, d}
            else
                --if the PDF page number is back to 1 clean up
                if page number of PDF attributes of myPDFPage = myFirstPage then
                    tell myPage to delete
                    set myDone to true
                end if
            end if
            --duplicates the placed page, gives 1,1,2,2,3,3 etc
            try
                tell myPage to duplicate to before myPage
            end try
            set myCounter to myCounter + 1
        end repeat
    end tell
end myPlacePDF
==================================