ICal and BIRTHDAYS...HELP!

Question

OK, iCal 2.02 and i understand the names must be put into the Address book to get them into the NON EDITABLE iCal, but WHAT if i have 4 brothers and they all have wives and 5 kids...i MUST enter a card for each just to put the birthdays in? Is this correct or am i missing something? What have other's done?
Is it time to go to MS Entourage?

Answer 1

Hi Steven,
I agree with you. That is why I wrote the Applescript below. It makes a calendar called myBirthdays in iCal and copies any new birthdays from Address Book when it is run. The calendar is editable, so you can add extra birthdays to it. When you add birthdays to Address Book just run the script again.
If you like the script it can be saved as an application, so it can be run with one click.
Best wishes
John M
-- copy below this line into Script Editor --
-- myBirthday
-- Copy birthdays from Address Book to iCal
-- John Maisey -- 30 May 2005 -- for iCal 2
-- No longer deletes myBirthdays calendar.
-- Now checks for previous myBirthdays calendar.
-- Now checks for previously added birthdays.
set myDays to text returned of (display dialog "How many days notice for display alarm?" default answer 2)
tell application "Address Book"
set nameSet to (name of people whose birth date is not missing value)
set birthDays to (birth date of people whose birth date is not missing value)
end tell
tell application "iCal"
if name of calendars does not contain "myBirthdays" then make new calendar at the end of calendars with properties {title:"myBirthdays"}
set myBirthdays to calendar "myBirthdays"
repeat with aNum from 1 to length of birthDays
if summary of (events of myBirthdays) does not contain ((item aNum of nameSet) & "'s Birthday") as text then
set aBirthday to make new event at the end of myBirthdays with properties {summary:(item aNum of nameSet) & "'s Birthday", start date:(item aNum of birthDays), recurrence:"FREQ=YEARLY;INTERVAL=1"}
set allday event of aBirthday to true
make new display alarm at the end of display alarms of aBirthday with properties {trigger interval:-1440 * myDays}
end if
end repeat
end tell