Identifying the Side Panel role from NWBC

Question

When an authorized user execute a Tcode with Side Panel assigned, the Side Panel will appear.
Question - Is there a standard report\mechanics whereby one could identify the Side Panel role associated with that Tcode?
Currently, my only method is to a brute search for the Application Alias via table AGR_HIER.   And then using description of the node to try to deduce what the Role is.  Works OK, but not exactly the most direct approach.
Cheers
Damean

Answer 1

This report lists all roles with a classic transaction as a triggering condition, either linked directly as APPLICATION_ALIAS or through the node ID.
report  zlistroles.
types: begin of nodefields,
  agr_name   type agr_name,
  object_id  type menu_num_8,
  reporttype type reporttype,
  report     type extdreport,
  appl_alias type menu_details_alias,
end of nodefields.
data lt_nodes   type table of nodefields.
data ls_nodes   type          nodefields.
data ls_nodes2  type          nodefields.
data lv_objid   type menu_num_8.
data lt_results type table of string.
data ls_results type string.
data lv_alias   type menu_details_alias.
data ls_match   type match_result.
data lv_length  type i.
select agr_name object_id reporttype report appl_alias
  from agr_hier into corresponding fields of table lt_nodes.
loop at lt_nodes into ls_nodes where appl_alias is not initial.
  if ls_nodes-appl_alias cp '{*}'.
    find first occurrence of regex `\{[0-9]{1,3}\}` in ls_nodes-appl_alias results ls_match.
    if sy-subrc eq 0.
      lv_length = ls_match-length - 1.
      lv_objid = ls_nodes-appl_alias+1(lv_length).
      read table lt_nodes into ls_nodes2 with key  agr_name = ls_nodes-agr_name
                                                  object_id = lv_objid.
      if sy-subrc eq 0 and
         ls_nodes2-reporttype eq 'TR'.
        write: / ls_nodes2-agr_name,
                 ls_nodes2-report.
      endif.
    else.
      find first occurrence of regex `\{TR=(.*)\}` in ls_nodes-appl_alias results ls_match.
      if sy-subrc eq 0.
        lv_length = ls_match-length - 5.
        lv_alias = ls_nodes-appl_alias+4(lv_length).
        split lv_alias at ';' into table lt_results.
        loop at lt_results into ls_results.
          write: / ls_nodes-agr_name,
                   ls_results.
        endloop.
      endif.
    endif.
  endif.
endloop.