Mass Creation of Variants

Question

I have hundreds of products that all have the same variant configurations, and I understandably don't want to pay someone to manually go through the WebTools interface to create all the variants.  After looking through the WebTools database, I am planning on creating a little SQL script that will copy the variant information from one product to another. 
1)  Select all records from Variant table where ConfigPartNo = 'itemtocopyfrom'
2)  Create new rows in Variant table that match the previously selected rows, switching out the ConfigPartNo to 'itemtocopyto'
3)  For each of the first selected VariantIDs in the Variant table, Select all the records in the PartsVariant table where VariantID = VariantID
4)  Duplicate each of those rows, substituting the new VariantID of the parts created in step 2
I can't find anyplace else that is affected by the creation of variants.  Will this work, or is there a better way to approach this?
Thanks,
Derek

Answer 1

In case anybody else is interested, I whipped up this in Access VBA today.  Basically all the form does is have two list boxes filled with all the products in WebTools.  You can only select one from the FROM listbox, but you can select as many products in the TO listbox as you want.  This code then loops through all of the selected TO products, duplicating all the variants settings of the FROM column. 
My code is only lightly commented and does very little error checking, but it does the job.  One thing to note if you end up using this code is that it doesn't check to see if it is duplicating variants, so if you click it twice or run it on a product that already has variants, it will add all of the variants from the FROM product.
Depending on how much I need to use this, I may extend it a little more so that I can choose to copy only certain variant categories rather than all variant categories, but we'll see.  If I do anything significant, I'll hopefully remember to come post it here.
If anyone is interested in the original Access database that runs this, just send me an email at derek AT seatability DOT com and I'll send it over to you.
Dim SQL As String
Dim con As ADODB.Connection
Dim rsVariantFrom As ADODB.Recordset
Dim rsVariantTo As ADODB.Recordset
Dim rsPartsVariantFrom As ADODB.Recordset
Dim rsPartsVariantTo As ADODB.Recordset
Dim rsAutoVariantID As ADODB.Recordset
Dim rsPartsMaster As ADODB.Recordset
Dim CopyFromProductID As String
Dim CopyToProductID As String
Dim AutoVariantID As Integer
Dim varItm As Variant
    CopyFromProductID = lstCopyFromPartNo.Value
    'Open Database Connection
    Set con = New ADODB.Connection
    con.ConnectionString = "Driver={SQL Server};" & _
               "Server=server;" & _
               "Database=database;" & _
               "Trusted_Connection=yes"
    con.Open
    For Each varItm In lstCopyToPartNo.ItemsSelected
        CopyToProductID = lstCopyToPartNo.ItemData(varItm)
        Set rsVariantFrom = New ADODB.Recordset
        SQL = "SELECT * FROM Variant WHERE ConfigPartNo = '" & CopyFromProductID & "'"
        rsVariantFrom.Open SQL, con, adOpenForwardOnly, adLockReadOnly
        Set rsVariantTo = New ADODB.Recordset
        SQL = "SELECT * FROM Variant WHERE ConfigPartNo = '0'"
        rsVariantTo.Open SQL, con, adOpenDynamic, adLockOptimistic
        Do Until rsVariantFrom.EOF
            ' Copy all the old Variant Fields, only changing the ConfigPartNo to the new ProductID
            rsVariantTo.AddNew
                rsVariantTo.Fields("ConfigPartNo").Value = CopyToProductID
                rsVariantTo.Fields("Description").Value = rsVariantFrom.Fields("Description").Value
                rsVariantTo.Fields("ImageURL").Value = rsVariantFrom.Fields("ImageURL").Value
                rsVariantTo.Fields("MarketingText").Value = rsVariantFrom.Fields("MarketingText").Value
                rsVariantTo.Fields("VariantType").Value = rsVariantFrom.Fields("VariantType").Value
                rsVariantTo.Fields("DefaultPartNo").Value = rsVariantFrom.Fields("DefaultPartNo").Value
                rsVariantTo.Fields("RequiredFlag").Value = rsVariantFrom.Fields("RequiredFlag").Value
                rsVariantTo.Fields("SortOrder").Value = rsVariantFrom.Fields("SortOrder").Value
                rsVariantTo.Fields("SynchFlag").Value = rsVariantFrom.Fields("SynchFlag").Value
                rsVariantTo.Fields("SynchDate").Value = rsVariantFrom.Fields("SynchDate").Value
            rsVariantTo.Update
            ' Retrieve most recent Autoincrement / Identity value from connection
            Set rsAutoVariantID = New ADODB.Recordset
            SQL = "SELECT IDENT_CURRENT('Variant')"
            rsAutoVariantID.CursorLocation = adUseServer
            rsAutoVariantID.Open SQL, con, adOpenForwardOnly, adLockReadOnly, adCmdText
            AutoVariantID = rsAutoVariantID.Fields(0).Value
            rsAutoVariantID.Close
            Set rsAutoVariantID = Nothing
            Set rsPartsVariantFrom = New ADODB.Recordset
            SQL = "SELECT * FROM PartsVariant WHERE VariantID = '" & rsVariantFrom.Fields("VariantID").Value & "'"
            rsPartsVariantFrom.Open SQL, con, adOpenForwardOnly, adLockReadOnly
            'Return an empty recordset to add the copied PartsVariant rows
            Set rsPartsVariantTo = New ADODB.Recordset
            SQL = "SELECT * FROM PartsVariant WHERE VariantID = '0'"
            rsPartsVariantTo.Open SQL, con, adOpenDynamic, adLockOptimistic
            ' Copy all the old PartsVariant fields, only changing the VariantID to the new VariantID
            Do Until rsPartsVariantFrom.EOF
                rsPartsVariantTo.AddNew
                   rsPartsVariantTo.Fields("VariantID").Value = AutoVariantID
                   rsPartsVariantTo.Fields("PartNo").Value = rsPartsVariantFrom.Fields("PartNo").Value
                   rsPartsVariantTo.Fields("DisplayText").Value = rsPartsVariantFrom.Fields("DisplayText").Value
                   rsPartsVariantTo.Fields("UseBaseFlag").Value = rsPartsVariantFrom.Fields("UseBaseFlag").Value
                   rsPartsVariantTo.Fields("BaseAdj").Value = rsPartsVariantFrom.Fields("BaseAdj").Value
                   rsPartsVariantTo.Fields("SortOrder").Value = rsPartsVariantFrom.Fields("SortOrder").Value
                   rsPartsVariantTo.Fields("SynchFlag").Value = rsPartsVariantFrom.Fields("SynchFlag").Value
                   rsPartsVariantTo.Fields("SynchDate").Value = rsPartsVariantFrom.Fields("SynchDate").Value
                rsPartsVariantTo.Update
                rsPartsVariantFrom.MoveNext
            Loop
            ' Close PartsVariant recordsets and destroy object
            rsPartsVariantFrom.Close
            rsPartsVariantTo.Close
            Set rsPartsVariantFrom = Nothing
            Set rsPartsVariantTo = Nothing
            rsVariantFrom.MoveNext
        Loop
        ' Set the master record of the item to be a Variant Master
        Set rsPartsMaster = New ADODB.Recordset
        SQL = "UPDATE PartsMaster " & _
                "SET VariantMasterFlag = 'Y' " & _
                "WHERE PartNo = '" & CopyToProductID & "'"
        rsPartsMaster.Open SQL, con
        ' Close Variant recordsets and destroy object
        rsVariantFrom.Close
        rsVariantTo.Close
        Set rsVariantFrom = Nothing
        Set rsVariantTo = Nothing
        Set rsPartsMaster = Nothing
    Next varItm
    con.Close
    Set con = Nothing