Pack Handling Units on Shipment

Question

Hi Experts,
We have a requirement to Pack the Bundles (SUB - HU's) onto TRUCKs (HU's) in Shipment.
I have been trying various FM's and also gone through the links with little success. In one of the links, friend Christopher has suggested to use 3 FMs in order to do this.
1. RV_SHIPMENT_VIEW
2. HU_PACKING_AND_UNPACKING
3. HU_POST 
I have tried this with some success but not in the way we wanted. Instead of packing BUNDLE - sub HU onto the TRUCK - HU in shipment, it was packing the bundle onto shipment.
Can someone please tell me how to achieve my requirement?
Thanks in advance.
Regards,
Lakshmi Narayana

Answer 1

Please check the following code snippet.
Certain attributes are hardcoded, please ensure that you change it accordingly to suit your needs. 
  types: VSEP_S_PITHU      TYPE PACKING_ITEM_HU.
  types: VSEP_T_OBJKEY     TYPE HUM_OBJECT_T.
  types: VSEP_S_OBJKEY     TYPE HUM_OBJECT.
  data:  l_PACKING_REQUEST type VSEP_S_PITHU.
  data:  l_VEKPVB          like VEKPVB.
  data:  l_header51        like HEADER51.
  data:  l_IT_OBJECTS      TYPE VSEP_T_OBJKEY.
  data   ls_objects        TYPE vsep_s_objkey.
  data   l_vbplk_a         like vbplk.
Read the packing details (HUs) for the shipment
  move 'IEQ' to st_shipment.
  move i_shipment to st_shipment-low.
  append st_shipment to t_shipment.
  CALL FUNCTION 'SD_PACKING_FOR_SHIPMENT'
    TABLES
      SHIPMENT_TAB = t_shipment
      VBPLK_TAB    = t_hu
      VBPLP_TAB    = t_hu_heirarchy
    EXCEPTIONS
      OTHERS       = 3.
  IF SY-SUBRC <> 0.
    raise NO_HUS_ON_SHIPMENT.
  ENDIF.
Sort table by sortl field to ensure that the order of
entries in the table reflect the true order of items
in the consist
  sort t_hu by sortl venum.
Find the top level (consist) HU
  read table t_hu
  into l_vbplk_a
  with key veltp = 'A'.
Pack all lower level HUs into the higher level
  loop at t_hu into st_hu
  where veltp ne 'A'.
    clear l_header51.
    l_header51-OBJECT  = '04'.
    l_header51-OBJKEY  = i_shipment.
    l_header51-PLANHU  = 'A'.
    l_header51-SPRAS   = sy-langu.
    l_header51-VTWEG   = '04'.
    l_header51-SPART   = '10'.
    l_header51-profile = '0006'.
    clear ls_objects.
    ls_objects-object   = '04'.
    ls_objects-objkey   = i_shipment.
    APPEND ls_objects to L_IT_objects.
    CALL FUNCTION 'V51P_READ_HUS_FOR_TRANSPORT'
      EXPORTING
        IF_LOCK_HU    = 'X'
        IF_FIRST      = 'X'
        IS_HEADER51   = l_header51
        IT_OBJECTS    = l_it_objects
      EXCEPTIONS
        HUS_LOCKED    = 1
        NOTHING_FOUND = 2
        FATAL_ERROR   = 3.
    if sy-subrc ne 0.
      raise hu_cannot_be_locked.
    endif.
    do 2 times.
  Do this twice as it is possible that the update of the
  delivery has not completed (even though commit and wait)
      CALL FUNCTION 'RV_SHIPMENT_VIEW'
        EXPORTING
          SHIPMENT_NUMBER             = i_shipment
          OPTION_TVTK                 = 'X'
          OPTION_TTDS                 = 'X'
          OPTION_ITEMS                = 'X'
          OPTION_STAWN_READ           = 'X'
          OPTION_SEGMENTS             = 'X'
          OPTION_PARTNERS             = 'X'
          OPTION_MESSAGES             = 'X'
          OPTION_PACKAGE_DIALOG       = 'X'
          OPTION_FLOW                 = 'X'
          OPTION_DELIVERY_LOCK        = 'X'
          OPTION_AUTHORITY_CHECK      = 'X'
          ACTIVITY                    = 'V'
          OPTION_NO_REFRESH           = ' '
          OPTION_IGNORE_MISSING_DELIV = 'X'
        EXCEPTIONS
          NOT_FOUND                   = 1
          NO_AUTHORITY                = 2
          DELIVERY_MISSING            = 3
          DELIVERY_LOCK               = 4
          OTHERS                      = 5.
      if sy-subrc eq 4.
        wait up to 1 seconds.
      else.
        exit.
      endif.
    enddo.
    CASE sy-subrc.
      when 0.
      when 4.
        raise DELIVERY_CANNOT_BE_LOCKED.
      when others.
        raise CANNOT_READ_SHIPMENT.
    endcase.
    clear l_packing_request.
    l_PACKING_REQUEST-VENUM = l_vbplk_a-venum.
    l_PACKING_REQUEST-EXIDV = l_vbplk_a-exidv.
    l_PACKING_REQUEST-VELIN = '3'.
    l_PACKING_REQUEST-SUB_HU_EXIDV = st_hu-exidv.
    l_PACKING_REQUEST-QUANTITY = 1.
    l_PACKING_REQUEST-ALTME = 'EA'.
    l_PACKING_REQUEST-VEANZ = 1.
    CALL FUNCTION 'HU_PACKING_AND_UNPACKING'
      EXPORTING
        IS_PACKING_REQUEST = l_packing_request
      EXCEPTIONS
        OTHERS             = 9.
    case sy-subrc.
      when 0.
      when others.
        message i999(zv) with 'Error while packing - return code' sy-subrc.
        raise ERROR_PACKING.
    endcase.
    CALL FUNCTION 'HU_PACKING_UPDATE'.
    commit work and wait.
  endloop.
ENDFUNCTION.