Problen in assigning partner function at the time of creation of lead .

Question

Hi ALL ,
          I have requirement , where as soon as bp will be created a lead has to be generated mentioning the BP as sales prospect (partner function) . I have to assign  employee reponsible partner  function too in lead , at the same time .
I have used BAPI :BAPI  BAPI_LEAD_CREATEMULTI  to create the lead .
But its not accepting the partner function as well as organisation details , giving error like Ref field for  Partner ,Orgman are not allowed.
Can any one tell me where and how can I assign the Partner function in case of my reuirement .
Thanks & Regards
Debasri sarkar

Answer 1

Hi Debasri,
I am able to develop a code to add a partner
Check this:
*- Data
  DATA: lt_partner            TYPE crmt_partner_comt.
  DATA: ls_partner            TYPE crmt_partner_com.
  DATA: lt_input_fields       TYPE CRMT_INPUT_FIELD_TAB.
  DATA: ls_input_fields       LIKE LINE OF lt_input_fields.
  DATA: ls_input_fields_names TYPE LINE OF CRMT_INPUT_FIELD_NAMES_TAB.
  DATA: LV_Guid type CRMT_OBJECT_GUID.
  DATA: LV_AddPartner type NOTES-UDATE.
  DATA : lt_orderadm_h TYPE CRMT_ORDERADM_H_COMT,
         ls_orderadm_h like line of lt_orderadm_h,
         gt_obj_guids TYPE  crmt_object_guid_tab.
   LV_Guid = '96CB40512AA2BD4C95EEE26BFD8E6187'.
   LV_AddPartner = '00000012'.
*- Partner info
  ls_partner-ref_kind = 'A'.
  ls_partner-kind_of_entry = 'C'.
  ls_partner-no_type = 'BP'.
  ls_partner-display_type = 'BP'.
  ls_partner-ref_guid = LV_Guid.
  ls_partner-ref_partner_fct = LV_AddPartner.
  ls_partner-partner_fct = LV_AddPartner.
  ls_partner-PARTNER_NO = '0000409993'.
  INSERT ls_partner INTO TABLE lt_partner.
*- Input Fields info
*  ls_input_fields-ref_handle = '1'.
  ls_input_fields-ref_guid = LV_Guid.
  ls_input_fields-ref_kind = 'A'.
  ls_input_fields-objectname = 'PARTNER'.
  CONCATENATE ls_partner-ref_partner_handle LV_AddPartner
              INTO ls_input_fields-logical_key.
  ls_input_fields_names-fieldname = 'PARTNER_FCT'.
  INSERT ls_input_fields_names INTO TABLE ls_input_fields-field_names.
  ls_input_fields_names-fieldname = 'NO_TYPE'.
  INSERT ls_input_fields_names INTO TABLE ls_input_fields-field_names.
  ls_input_fields_names-fieldname = 'DISPLAY_TYPE'.
  INSERT ls_input_fields_names INTO TABLE ls_input_fields-field_names.
  ls_input_fields_names-fieldname = 'PARTNER_NO'.
  INSERT ls_input_fields_names INTO TABLE ls_input_fields-field_names.
  ls_input_fields_names-fieldname = 'KIND_OF_ENTRY'.
  INSERT ls_input_fields_names INTO TABLE ls_input_fields-field_names.
  INSERT ls_input_fields INTO TABLE lt_input_fields.
*- Make the changes in memory
  CALL FUNCTION 'CRM_ORDER_MAINTAIN'
    EXPORTING
      IT_PARTNER        = lt_partner
    CHANGING
      ct_orderadm_h     = lt_orderadm_h
      CT_INPUT_FIELDS   = lt_input_fields
    EXCEPTIONS
      ERROR_OCCURRED    = 1
      DOCUMENT_LOCKED   = 2
      NO_CHANGE_ALLOWED = 3
      NO_AUTHORITY      = 4
      OTHERS            = 5.
  IF SY-SUBRC <> 0.
      Write 'Error!'.
  ENDIF.
* Get guids
  LOOP AT lt_orderadm_h INTO ls_orderadm_h.
    INSERT ls_orderadm_h-GUID INTO TABLE gt_obj_guids.
  ENDLOOP.
  CALL FUNCTION 'CRM_ORDER_SAVE'
    EXPORTING
      it_objects_to_save = gt_obj_guids
    EXCEPTIONS
      document_not_saved = 1.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'.
Hope this solves the issue.
Regards,
Saumya