Setting up number range for projects in cProjects

Question

Hi,
I am new to cProjects & my apologies if my question may sound very naive. My client wants an alpha-numeric number range to be set up for numbering of projects. Is this possible & if yes how? Which is the object for setting the number range? (I believe the transaction in "SNRO")
Thanking you for taking a note of my querry.
Regards
Deepak

Answer 1

Sample Code Method SET_DEFAULTS_UPON_CREATION
Method IF_EX_DPR_ATTRIBUTES~SET_DEFAULTS_UPON_CREATION
*/ This method is called when creating a new project element (i.e. project definition,
*/ phase, task, etc) and can be used to fill in default values for standard as well
*/ as customer defined data fields.
*/ This implementation is provided to assign customer specific numbers to project
*/ elements.
*/ It's interesting to note that when this method is called, the external ID of the
*/ object has already been determined and assigned by the default numbering services
*/ class CL_DPR_NUMBERING_SERVICES. It is also interesting to note that if a user
*/ specified an ID for the object through the user interface, changing the identifier
*/ in this method will have no effect -- meaning the user specified ID will still be
*/ assigned to the object.
*/ Only the example for Project Definition is provided.  For other project elements,
*/ insert similar code between the Beginning and End comments below.  In addition,
*/ the filter for this BADI implementation must be updated to include any other
*/ project element for which custom number assignment is desired.
  DATA:
    lr_parent              TYPE REF TO if_dpr_common,
    lr_project             TYPE REF TO cl_dpr_project,
    lr_approval            TYPE REF TO cl_dpr_approval,
    lr_individual_approval TYPE REF TO cl_dpr_individual_approval,
    lr_phase               TYPE REF TO cl_dpr_phase,
    lr_task                TYPE REF TO cl_dpr_task,
    lr_checklist           TYPE REF TO cl_dpr_checklist,
    lr_checklist_item      TYPE REF TO cl_dpr_checklist_item,
    LV_NUMBER              TYPE DPR_TV_EXTID,
    LV_NUMTEXT             TYPE CGPL_EXTID,
    LV_INTERVAL            TYPE NRIV.
  FIELD-SYMBOLS:
    <ls_project_attrs>             TYPE dpr_ts_project_int,
    <ls_phase_attrs>               TYPE dpr_ts_phase_int,
    <ls_task_attrs>                TYPE dpr_ts_task_int,
    <ls_checklist_attrs>           TYPE dpr_ts_checklist_int,
    <ls_checklist_item_attrs>      TYPE dpr_ts_checklist_item_int,
    <ls_approval_attrs>            TYPE dpr_ts_approval_int,
    <ls_individual_approval_attrs> TYPE dpr_ts_individual_approval_int.
*/  Determine which project element (object category) is being processed
  CASE flt_val.
    WHEN cl_dpr_co=>sc_ot_project.
      ASSIGN cs_attributes TO <ls_project_attrs>.
      lr_project ?= ir_common.
*/ Beginning of custom project number assignment.
*/    In this example, the default system numbering is manipulated to
*/    produce the Project Number...
*/    Get info regarding the number range for operative projects...
      CALL FUNCTION 'NUMBER_GET_INFO'
        EXPORTING
          NR_RANGE_NR              = 'DO'
          OBJECT                   = 'DPR_EXTID'
*         SUBOBJECT                = ' '
*         TOYEAR                   = '0000'
        IMPORTING
          INTERVAL                 = LV_INTERVAL
        EXCEPTIONS
          INTERVAL_NOT_FOUND       = 1
          OBJECT_NOT_FOUND         = 2
          OTHERS                   = 3.
      IF NOT SY-SUBRC IS INITIAL.
        RAISE EXCEPTION TYPE CX_DPR_FATAL_ERROR
          EXPORTING
            TEXTID = CX_DPR_FATAL_ERROR=>SC_INVALID_PARAMETERS.
      ENDIF.
*/    Strip off the year that has been appended to the object number
*/    by the default numbering services...
      write <ls_project_attrs>-project_id(20) to lv_number.
*/    Get the incremental number of the project from the number range...
      lv_number = lv_number - LV_INTERVAL-FROMNUMBER.
*/    Format the number according to customer specific requirements:
*/    In this example the number is PROJ-<inc num> where <inc num>
*/    is the incremental number of the project (i.e. for the 33rd project
*/    created, the <inc num> is 33).
      WRITE lv_number to lv_numtext no-zero.
      condense lv_numtext.
      CONCATENATE 'PROJ' lv_numtext INTO lv_numtext SEPARATED BY '-'.
      TRY.
          CALL METHOD LR_PROJECT->SET_PROJECT_ID
            EXPORTING
              IV_PROJECT_ID              = lv_numtext.
      CATCH CX_DPR_OBJECT_UPDATE_ERROR .
          RETURN.
      ENDTRY.
*/ End of custom project number assignment.
    WHEN cl_dpr_co=>sc_ot_phase.
      ASSIGN cs_attributes TO <ls_phase_attrs>.
      lr_phase ?= ir_common.
*/ Beginning of custom phase number assignment.
*/ End of custom phase number assignment.
    WHEN cl_dpr_co=>sc_ot_approval.
      ASSIGN cs_attributes TO <ls_approval_attrs>.
      lr_approval ?= ir_common.
*/ Beginning of custom approval number assignment.
*/ End of custom approval number assignment.
    WHEN cl_dpr_co=>sc_ot_individual_approval.
      ASSIGN cs_attributes TO <ls_individual_approval_attrs>.
      lr_individual_approval ?= ir_common.
*/ Beginning of custom individual approval number assignment.
*/ End of custom individual approval number assignment.
    WHEN cl_dpr_co=>sc_ot_checklist.
      ASSIGN cs_attributes TO <ls_checklist_attrs>.
      lr_checklist ?= ir_common.
*/ Beginning of custom checklist number assignment.
*/ End of custom checklist number assignment.
    WHEN cl_dpr_co=>sc_ot_checklist_item.
      ASSIGN cs_attributes TO <ls_checklist_item_attrs>.
      lr_checklist_item ?= ir_common.
*/ Beginning of custom checklist item number assignment.
*/ End of custom checklist item number assignment.
    WHEN cl_dpr_co=>sc_ot_task.
      ASSIGN cs_attributes TO <ls_task_attrs>.
      lr_task ?= ir_common.
*/ Beginning of custom task number assignment.
*/ End of custom task number assignment.
  ENDCASE.
ENDMETHOD.