Track documents based on a purchase order

Question

Hi,
One of my customers asked me yesterday if there is a good way to follow the steps from a purchase order to goods reciept and AP invoice? If you have a large purchase order with many items and only a few of them are copied to goods reciept PO at a time, and you have several goods reciepts PO and many invoices. How can one best track all of these documents and get a good overview?
I tried using Drag & Relate, but it's not good enough to get the whole picture. So I would really appreciate if you have some tips, or if there could be a way to create a report for which documents are based on a purchase order.
Best regards,
Lena-Marie

Answer 1

Hello Lena-Marie - welcome to the forum.  You might want to start with this and add some more into and/or change the WHERE clause to pull up the information you need.   Such as T2.DocNum =
This SQL was restricted to display only some open items...
If you need more help changing this particular SQL, just contact me directly through my business card's alternative...
Regards - Zal
--E-PU Audit Review of Purchase Orders to AP Invoices Workstation Ver 1 ZP 2011 02 14
--DESCRIPTION:  SQL shows ONLY those lines from the Purchase Orders or Goods Receipts or AP Invoice that are still open and needing to be worked.
--AUTHOR(s):
--Version 1 Zal Parchem 14 Feb 2011
SELECT
T2.DocNum AS 'Purch Ord',
T2.DocDate AS ' Ord Date',
T1.ShipDate AS 'Expected',
T1.ItemCode AS 'Product',
CASE
WHEN T1.[LineStatus] = 'O' THEN 'Open'
WHEN T1.LineStatus = 'C' THEN 'Closed'
ELSE 'Error'
END AS 'Row Stat',
CASE
WHEN T2.Canceled = 'Y'
THEN 'Yes'
ELSE ' '
END AS 'Cancelled?',
T1.LineNum+1 AS 'Line',
T1.Quantity,
T1.OpenQty AS 'Open Qty',
T4.DocNum AS 'Goods Rcpt',
T4.DocDueDate AS 'Rcpt Date',
CASE
WHEN T3.[LineStatus] = 'O' THEN 'Open'
WHEN T3.LineStatus = 'C' THEN 'Closed'
ELSE ' '
END AS 'Row Stat',
CASE
WHEN T4.Canceled = 'Y'
THEN 'Yes'
ELSE ' '
END AS 'Cancelled?',
T3.LineNum + 1 AS 'Line',
T3.Quantity,
T6.DocNum AS 'Return',
T5.LineNum +1 AS 'Line',
CASE
WHEN T5.[LineStatus] = 'O' THEN 'Open'
WHEN T5.LineStatus = 'C' THEN 'Closed'
ELSE ' '
END AS 'Row Stat',
CASE
WHEN T6.Canceled = 'Y'
THEN 'Yes'
ELSE ' '
END AS 'Cancelled?',
T5.Quantity,
T8.DocNum AS 'AP Invoice',
T7.LineNum + 1 AS 'Line',
T7.Quantity,
T10.DocNum AS 'AP Cred Memo',
T9.LineNum + 1 AS 'Line',
T9.Quantity
FROM POR1 T1
LEFT OUTER JOIN OPOR T2
ON T1.DocEntry = T2.DocEntry
LEFT OUTER JOIN PDN1 T3
ON T2.DocEntry = T3.BaseEntry
AND T1.LineNum = T3.BaseLine
AND T1.ItemCode = T3.ItemCode
LEFT OUTER JOIN OPDN T4
ON T3.DocEntry = T4.DocEntry
LEFT OUTER JOIN RPD1 T5
ON T4.DocEntry = T5.BaseEntry
AND T3.LineNum = T5.BaseLine
AND T3.ItemCode = T5.ItemCode
LEFT OUTER JOIN ORPD T6
ON T5.DocEntry = T6.DocEntry
LEFT OUTER JOIN PCH1 T7
ON T4.DocEntry = T7.BaseEntry
AND T3.LineNum = T7.BaseLine
AND T3.ItemCode = T7.ItemCode
LEFT OUTER JOIN OPCH T8
ON T7.DocEntry = T8.DocEntry
LEFT OUTER JOIN RPC1 T9
ON T8.DocEntry = T9.BaseEntry
AND T7.LineNum = T9.BaseLine
AND T7.ItemCode = T9.ItemCode
LEFT OUTER JOIN ORPC T10
ON T9.DocEntry = T10.DocEntry
WHERE
(T1.LineStatus = 'O' OR T3.LineStatus = 'O' OR T5.LineStatus = 'O')
ORDER BY
T2.DocNum,
T1.LineNum,
T4.DocNum,
T3.LineNum,
T6.DocNum,
T5.LineNum,
T8.DocNum,
T7.LineNum,
T10.DocNum,
T9.LineNum
FOR BROWSE