Trying to Create a Macro...it's not going well

Question

Hello! 
I am trying to create a macro for this Questionnaire I am building. I need it to pull information from 3 or so different tables in word (all in same doc) and export them into Excel. I have fields that gather personal info like Name, Address, Telephone Number,
Email, etc, but also fields that take info like Tax Filing State and Tax ID number. There will be about 40 fields in all when the questionnaire is done. Each field is being filled in using a legacy tool- text form field. Is there some sort of macro shell I
can use that I can fill in with each field when I have completed it? I have office 2013, not sure if that matters.
Thank you!

Answer 1

The following Excel macro will pull the data from all formfields in all Word files in a specified folder into the active worksheet. To run it, simply press Alt-F8 and choose the 'GetFormData' macro. You'll be asked to navigate to the source folder.
Once you've done that, the macro will populate the worksheet. The first row will be left alone, so you can populate it with headings before or after running the macro.
Sub GetFormData()
     'Note: this code requires a reference to the Word object model
    Application.ScreenUpdating = False
    Dim wdApp As New Word.Application
    Dim wdDoc As Word.Document
    'Dim CCtrl As Word.ContentControl
    Dim FmFld As Word.FormField
    Dim strFolder As String, strFile As String
    Dim WkSht As Worksheet, i As Long, j As Long
    strFolder = GetFolder
    If strFolder = "" Then Exit Sub
    Set WkSht = ActiveSheet
    i = WkSht.Cells(WkSht.Rows.Count, 1).End(xlUp).Row
    strFile = Dir(strFolder & "\*.doc", vbNormal)
    While strFile <> ""
        i = i + 1
        Set wdDoc = wdApp.Documents.Open(Filename:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
        With wdDoc
            j = 0
            'For Each CCtrl In .ContentControls
                'j = j + 1
                'WkSht.Cells(i, j) = CCtrl.Range.Text
            'Next
            For Each FmFld In .FormFields
                j = j + 1
                WkSht.Cells(i, j) = FmFld.Result
            Next
        End With
        wdDoc.Close SaveChanges:=False
        strFile = Dir()
    Wend
    wdApp.Quit
    Set wdDoc = Nothing: Set wdApp = Nothing: Set WkSht = Nothing
    Application.ScreenUpdating = True
End Sub
Function GetFolder() As String
    Dim oFolder As Object
    GetFolder = ""
    Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
    If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
    Set oFolder = Nothing
End Function
Note the commented-out code that allows the macro to work with content controls as well or instead.
Cheers
Paul Edstein
[MS MVP - Word]