WebUtil and Microsoft Excel: Setting cell border properties

Question

I'm using the CLIENT_OLE2 package shipped with WebUtil to create a Microsoft Excel spreadsheet from an Oracle 10g Form and, so far, have managed to:
- Create multiple worksheets
- Populate cells with values and formulae
- Format cells, including setting font name and size, setting bold italic and underline attributes
The final requirement is to set a border on a cell or group of cells, but this is where I'm stumped. My code thus far looks like this:
DECLARE
  l_application   CLIENT_OLE2.OBJ_TYPE ;
  l_workbooks     CLIENT_OLE2.OBJ_TYPE ;
  l_workbook      CLIENT_OLE2.OBJ_TYPE ;
  l_worksheets    CLIENT_OLE2.OBJ_TYPE ;
  l_worksheet     CLIENT_OLE2.OBJ_TYPE ;
  l_cell          CLIENT_OLE2.LIST_TYPE ;
  l_borders       CLIENT_OLE2.OBJ_TYPE ;
BEGIN   
  l_application := CLIENT_OLE2.CREATE_OBJ('Excel.Application') ;
  l_workbooks := CLIENT_OLE2.GET_OBJ_PROPERTY(l_application,'Workbooks') ;
  l_workbook := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbooks,'Add') ;
  l_worksheets := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbook,'Worksheets') ;
  l_arguments := CLIENT_OLE2.CREATE_ARGLIST ;
  CLIENT_OLE2.ADD_ARG(l_arguments,'Sheet1') ;
  l_worksheet := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbook,'Worksheets',l_arguments) ;
  CLIENT_OLE2.DESTROY_ARGLIST(l_arguments) ;
--  Select cell A1
  l_arguments := CLIENT_OLE2.CREATE_ARGLIST ;
  CLIENT_OLE2.ADD_ARG(l_arguments,1) ;
  CLIENT_OLE2.ADD_ARG(l_arguments,1) ;
  l_cell := CLIENT_OLE2.GET_OBJ_PROPERTY(l_worksheet,'Cells',l_arguments) ;
  CLIENT_OLE2.DESTROY_ARGLIST(l_arguments) ;
  l_borders := CLIENT_OLE2.GET_OBJ_PROPERTY(p_cells,'Borders') ;
--  What happens next...?
--  Clean up
  CLIENT_OLE2.RELEASE_OBJ(l_borders) ;
  CLIENT_OLE2.RELEASE_OBJ(l_worksheet) ;
  CLIENT_OLE2.RELEASE_OBJ(l_worksheets) ;
  CLIENT_OLE2.RELEASE_OBJ(l_workbook) ;
  CLIENT_OLE2.RELEASE_OBJ(l_workbooks) ;
  CLIENT_OLE2.RELEASE_OBJ(l_application) ;
END ;I'd be obliged for a pointer in the right direction!

Answer 1

Well, in spite of 80-odd views, it looks like I've answered my own question.
The borders around a range of cells in Excel are actually separate elements of the Borders object. You need to specify which border you want and set it individually. The code below draws a border around cells A1 to C3. Note the constants defined at the top of the listing; these are the "actual" values of the corresponding Excel constants that are referenced in the VBA code if you draw the border by hand while recording a macro.
Enjoy!
DECLARE
  c_automatic     CONSTANT NUMBER := -4105 ;  -- ColorIndex = xlAutomatic
  c_thin          CONSTANT NUMBER := 2 ;      -- Weight = xlThin
  c_medium        CONSTANT NUMBER := -4138 ;  -- Weight = xlMedium
  c_thick         CONSTANT NUMBER := 4 ;      -- Weight = xlThick
  c_continuous    CONSTANT NUMBER := 1 ;      -- LineStyle = xlContinuous
  c_edge_left     CONSTANT NUMBER := 7 ;      -- Border = xlEdgeLeft
  c_edge_top      CONSTANT NUMBER := 8 ;      -- Border = xlEdgeTop
  c_edge_bottom   CONSTANT NUMBER := 9 ;      -- Border = xlEdgeBottom
  c_edge_right    CONSTANT NUMBER := 10 ;     -- Border = xlEdgeRight
  l_application   CLIENT_OLE2.OBJ_TYPE ;
  l_workbooks     CLIENT_OLE2.OBJ_TYPE ;
  l_workbook      CLIENT_OLE2.OBJ_TYPE ;
  l_worksheets    CLIENT_OLE2.OBJ_TYPE ;
  l_worksheet     CLIENT_OLE2.OBJ_TYPE ;
  l_range         CLIENT_OLE2.LIST_TYPE ;
  PROCEDURE draw_border (
    p_range       IN CLIENT_OLE2.LIST_TYPE,
    p_side        IN NUMBER,
    p_weight      IN NUMBER)
  IS
    l_edge      CLIENT_OLE2.LIST_TYPE ;
    l_border    CLIENT_OLE2.OBJ_TYPE ;
  BEGIN
    l_edge := CLIENT_OLE2.CREATE_ARGLIST ;
    CLIENT_OLE2.ADD_ARG(l_edge,p_side) ;
    l_border := CLIENT_OLE2.GET_OBJ_PROPERTY(l_range,'Borders',l_edge) ;
    CLIENT_OLE2.DESTROY_ARGLIST(l_edge) ;
    CLIENT_OLE2.SET_PROPERTY(l_border,'LineStyle',c_continuous) ;
    CLIENT_OLE2.SET_PROPERTY(l_border,'Weight',p_weight) ;
    CLIENT_OLE2.SET_PROPERTY(l_border,'ColorIndex',c_automatic) ;
    CLIENT_OLE2.RELEASE_OBJ(l_border) ;
  END draw_border ;
BEGIN   
  l_application := CLIENT_OLE2.CREATE_OBJ('Excel.Application') ;
  l_workbooks := CLIENT_OLE2.GET_OBJ_PROPERTY(l_application,'Workbooks') ;
  l_workbook := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbooks,'Add') ;
  l_worksheets := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbook,'Worksheets') ;
  l_arguments := CLIENT_OLE2.CREATE_ARGLIST ;
  CLIENT_OLE2.ADD_ARG(l_arguments,'Sheet1') ;
  l_worksheet := CLIENT_OLE2.GET_OBJ_PROPERTY(l_workbook,'Worksheets',l_arguments) ;
  CLIENT_OLE2.DESTROY_ARGLIST(l_arguments) ;
--  Select the box with top-left of A1 and bottom-right of C3.
  l_arguments := CLIENT_OLE2.CREATE_ARGLIST ;
  CLIENT_OLE2.ADD_ARG(l_arguments,'A1:C3') ;
  l_range := CLIENT_OLE2.GET_OBJ_PROPERTY(p_worksheet,'Range',l_arguments) ;
  CLIENT_OLE2.DESTROY_ARGLIST(l_arguments) ;
--  Draw border along the left edge of cells in range
  draw_border(l_range,c_edge_left,c_thick) ;
--  Draw border along the top edge of cells in range
  draw_border(l_range,c_edge_top,c_thick) ;
--  Draw border along the right edge of cells in range
  draw_border(l_range,c_edge_right,c_thick) ;
--  Draw border along the bottom edge of cells in range
  draw_border(l_range,c_edge_bottom,c_thick) ;
--  Clean up
  CLIENT_OLE2.RELEASE_OBJ(l_range) ;
  CLIENT_OLE2.RELEASE_OBJ(l_worksheet) ;
  CLIENT_OLE2.RELEASE_OBJ(l_worksheets) ;
  CLIENT_OLE2.RELEASE_OBJ(l_workbook) ;
  CLIENT_OLE2.RELEASE_OBJ(l_workbooks) ;
  CLIENT_OLE2.RELEASE_OBJ(l_application) ;
END ;It's worth pointing out that the code above has been culled from my specific procedure and has been simplified. It hasn't been tested, although the DRAW_BORDER nested procedure has been copied straight from working code.