824pp document to pdf as single pages

Question

Hello
I am after some help if possible. We are producing a catalogue that is 824 pages in length. We do not have 1 document with 824 pages, we have split it into smaller sizes. However, we are using on online proofing system and have been asked if we can upload our high res pdf's as single page documents. This will help speed up the proofing and will make ftp transfer of the files a lot easier. Is there a way to take a multi page document and export it as a high res pdf to PDFX1A standard as single pages. For example, if one section is 32 pages we need to export it as 32 separate pdf's.
Thanks in anticipation
Gary

Answer 1

Here's something I've posted this AS before and it works for me in CS2. Put the document you wish to make single pages of in its own folder, open the document then run the attached script. PDF files will be placed in folder that the document's in. Good luck. I can't claim ownership for this script. I picked it up from another forum or thread.
tell application "Adobe InDesign CS2"
set allPresets to name of every PDF export preset
set thePreset to choose from list allPresets
if thePreset = false then
beep
error number -128
else
set the thePreset to item 1 of thePreset
end if
try
set thepath to (full name of document 1) as string
on error
set theDesk to path to desktop as string
set thepath to theDesk & (name of document 1) as string
end try
if thepath ends with ".indd" then
set thepath to text 1 thru -6 of thepath
end if
set pageCount to pages per document of document preferences of document 1
repeat with i from 1 to pageCount
set page range of PDF export preferences to i as string
export document 1 to file (thepath & "-" & i & ".pdf") format PDF type using PDF export preset thePreset without showing options
end repeat
beep
display dialog "Finshed." buttons {"OK"} default button 1
end tell