Applescript: isn't in the correct format?

Question

Hi, i wanted to make a script that would randomly take an image from a fodler of life drawing models and landscript that i would then have to draw.
Everything seemed to be working fine with it but all of the sudden im getting 2 different messages whenever the script is run.
The first message i get is:
The file couldn’t be opened because it isn’t in the correct format.
The file might be corrupted, truncated, or in an unexpected format.
I went to the image that wasn't working and double clicked it and it opened fine in Preview.app so i wasn't sure why it wasn't working with the script but was with the double click.
the other message im getting is a permissions message but i can't seem to get that to come back up at the moment to copy and paste it here, but it looks like the normal "you do not have permission to view this file" sort of thing.
i've checked permissions and i've repaired them just encase but no issues or warning came up so im not sure what the issue with the permissions could be.
here is the script i have used to make it select and open a random image.
with timeout of 36000 seconds
    tell application "Finder"
        activate
        if (count items) of folder "MonkeyBook Pro:Users:Monkey:Documents:Guardian Classes:Drawing Tasks:" is 0 then
            display dialog "You Have Completed All Available Drawning Tasks, Please Add More To Folder" with icon stop buttons {"Open Folder", "Random Image Site", "Close"}
            set the button_pressed to button returned of the result
            if the button_pressed is "Open Folder" then
                tell application "Finder"
                    activate
                    open "MonkeyBook Pro:Users:Monkey:Documents:Guardian Classes:Drawing Tasks"
                end tell
            else if the button_pressed is "Random Image Site" then
                tell application "Safari"
                    activate
                    open location "http://photo.net/photodb/random-photo?category=NoNudes"
                end tell
            end if
        else
            activate
            set question to display dialog "Time For Some Drawing
Warning These Photos May Be Of An Adult Nature" with icon stop buttons {"Not Possible At The Moment", "OK"}
            set answer to button returned of question
            if answer is equal to "OK" then
                tell application "Finder"
                    set randomImage to some file of folder "MonkeyBook Pro:Users:Monkey:Documents:Guardian Classes:Drawing Tasks"
                end tell
                tell application "Preview"
                    open randomImage
                end tell
                tell application "Finder"
                    move randomImage to folder "MonkeyBook Pro:Users:Monkey:Documents:Guardian Classes:Completed Tasks:"
                end tell
            end if
        end if
    end tell
end timeout
Anyone got any idea why this might be happening?

Answer 1

I think the issue comes from the fact that the picture is moved to the Completed Tasks folder before Preview.app has had time to open it properly. So, if I'm right, adding a short delay before moving the picture should fix the issue.
Maybe you might want to try this simplified version of your script:
set DrawingTasks to POSIX file "/Users/Monkey/Documents/Guardian Classes/Drawing Tasks"
set CompletedTasks to POSIX file "/Users/Monkey/Documents/Guardian Classes/Completed Tasks"
tell application "Finder"
    activate
    if (count items of folder DrawingTasks) is 0 then
        display dialog "You Have Completed All Available Drawning Tasks, Please Add More To Folder" with icon stop buttons {"Open Folder", "Random Image Site", "Close"}
        set the button_pressed to button returned of the result
        if the button_pressed is "Open Folder" then
            open folder DrawingTasks
        else if the button_pressed is "Random Image Site" then
            tell application "Safari"
                activate
                open location "http://photo.net/photodb/random-photo?category=NoNudes"
            end tell
        end if
    else
        set question to display dialog "Time For Some Drawing." & return & return & "Warning: These Photos May Be Of An Adult Nature" with icon stop buttons {"Not Possible At The Moment", "OK"}
        set answer to button returned of question
        if answer is equal to "OK" then
            set randomImage to some file of folder DrawingTasks
            tell application "Preview" to open randomImage
            delay 2 -- adjust to fit your needs
            move randomImage to CompletedTasks
        end if
    end if
end tell