Base64 and dbms_output problem

Question

Hello,
I'm trying to write a function that generate HTML content for sending inside a mail. This HTML content needs to have some picture inside it. To do so I'm using some conversion function from blob to base 64 encoding. To be sure that my function is working properly, I'm trying to execute it inside Oracle SQL developer.
The problem is that whenever I'm tying to show up any base64 content via dbms_output.put_line I got:
ORA-06502: PL/SQL: numeric or value error
ORA-06512: at line xxx
06502. 00000 - "PL/SQL: numeric or value error%s"
Here is the part of the code where I'm trying to open file and convert it inside base64 content
With those variable:
    -- locale variables
    vc_mail_content       CLOB;
    vc_file_folder        VARCHAR2(100);
    vb_lFile              BFILE;
    vc_image_content      CLOB;
    vb_image_content      BLOB;Code:
FOR c_file_name IN
          ( SELECT filename, folder
             FROM MO_ITEM_IMAGES
             WHERE item_id = R_lots.item_id)
         LOOP
            dbms_output.put_line('attachement '||c_file_name.fileName);
            vb_image_content := NULL;
            DBMS_LOB.CREATETEMPORARY(vb_image_content,true);
            vb_lfile  := BFILENAME('MO_DIR', 'webdav/'||c_file_name.folder||'/'||c_file_name.fileName);
            DBMS_LOB.OPEN(vb_lfile, DBMS_LOB.LOB_READONLY);
            DBMS_LOB.OPEN(vb_image_content, DBMS_LOB.LOB_READWRITE);
            DBMS_LOB.LOADFROMFILE(     DEST_LOB => vb_image_content,
                        SRC_LOB  => vb_lfile,
                        AMOUNT   => DBMS_LOB.GETLENGTH(vb_lfile));
            DBMS_LOB.CLOSE(vb_lfile);
            vc_image_content := zzz_mails.getbase64String(vb_image_content);
            --/!\ This DBMS output creates the error /!\
            dbms_output.put_line(vc_image_content);
            DBMS_LOB.CLOSE(vb_image_content);
            vc_mail_content := vc_mail_content||vc_image_content;
         END LOOP; Whenever it reach the DBMS_output.put_line, I got the error.
The getbase64String function is a function that translate from blob to base64 clob
Can someone help me to solve this problem?
Thank you
Edited by: user13444434 on 3 juil. 2011 08:42

Answer 1

DBMS_OUTPUT can not print CLOB in thay way. YOu can use a function like this:
PROCEDURE print_clob(p_clob in clob) as
    l_offset number default 1;
  BEGIN
    loop
      exit when l_offset > dbms_lob.getlength(p_clob);
      dbms_output.put_line(dbms_lob.substr(p_clob, 255, l_offset));
      l_offset := l_offset + 255;
    end loop;
  END print_clob;and call that in your original procedure.