Check Dates in a document

Question

Hello, I need to check all the dates (day/date/month) in a document to a list of predetermined fixtures (around 200 dates) to make sure they are correct.
My plan is to search the document using the following grep find...
(Monday|Tuesday|Wednesday|Thursday|Friday|Saturday|Sunday)\s(1|2|3|4|5|6|7|8|9|10|11|12|13 |14|15|16|17|18|19|20|21|22|23|24|25|26|27|28|29|30|31)\s(January|February|March|April|May |June|July|August|September|October|November|December)
...then check the text found against my list of fixture, if its not found it will show an alert.
Can anyone tell me if there is a better way and where they would start scripting in Applescript?
many thanks
LJ

Answer 1

Wouldn't it be easier to search on...
(Monday|Tuesday|Wednesday|Thursday|Friday|Saturday|Sunday)\s[1-3]?\d\s(January|February|Ma rch|April|May|June|July|August|September|October|November|December)
instead of enumerating all 31 days? Same effect, I think, although admittedly it will find thround 39 instead of 31...
Script-wise, Jong's plan is good. Arrays are called lists in AS. So the bare bones of it would be something like this, I think:
tell application "Adobe InDesign CS3"
  tell active document
    display dialog "Find bad dates or clear bad dates color?" buttons {"Clear", "Find"} default button 2
    if button returned of result = "Find" then
      set badCount to 0
      set myGrepString to "(Monday|Tuesday|Wednesday|Thursday|Friday|Saturday|Sunday)\\s[1-3]?\\d\\s(January|February|March|April|May|June|July|August|September|October|November|December)"
      set goodDateList to {"Monday 13 December", "Tuesday 15 February", "Monday 1 June"} --Fill with real ones
      try
        set mySwatch to make color with properties {name:"BAD DATES", model:spot, space:CMYK, color value:{0.0, 100.0, 0.0, 0.0}}
      end try
      tell application "Adobe InDesign CS3"
        set find grep preferences to nothing
        set change grep preferences to nothing
        set find what of find grep preferences to myGrepString
      end tell
      set foundList to find grep
      repeat with thisDate in foundList
        if goodDateList does not contain (thisDate as string) then
          set fill color of every character of thisDate to color "BAD DATES"
          set badCount to badCount + 1
        end if
      end repeat
      display dialog "Found "&badCount&" bad dates." buttons "OK" default button 1
    else
      try
        delete color "BAD DATES" replacing with color "Black"
      on error
        display dialog "Can't find BAD DATES color to delete."
      end try
    end if
  end tell
end tell
EDIT: Be careful copying this script! Whenever I copy it out of the browser, December gets a space in it and becomes Decembe r...