Copying From Info Panel

Question

Hi,
I created a Powerpoint for a class project at school. I downloaded about 100 random images from the web and saw that the source/url was in the cmd/I info panel. I wasn't sure which ones I'd use so I waited till I was done to copy the source/web site url from the info panel.
I'm just finishing and now find out I can't copy and past from this info panel! To copy by hand will take me way too long!
Is there a way to quickly get this info out of the file?
Thanks,
W

Answer 1

The mdls attribute name you are looking for is kMDItemWhereFroms. I wrote an AppleScript a while back to put up a dialog of the download URL, with the option to copy it to the clipboard:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFD891;
overflow: auto;"
title="this text can be pasted into the Script Editor">
property getSpecific : true -- show the specific download URL?
set aFile to quoted form of POSIX path of (choose file)
set theURL to (do shell script "mdls -name kMDItemWhereFroms -raw " & aFile)
if theURL is "(null)" then -- no attribute
set theURL to "(URL info not found)"
set theMessage to ""
else
if getSpecific then -- get the first item (the download URL)
set theMessage to "download "
set theURL to paragraph 2 of theURL
set here to offset of "\"" in theURL
set theURL to text (here + 1) thru -3 of theURL
else -- get the last item (the page/site URL)
set theMessage to "page/site "
set theURL to paragraph -2 of theURL
set here to offset of "\"" in theURL
set theURL to text (here + 1) thru -2 of theURL
end if
end if
if theURL is "(URL info not found)" then
set theButtons to {"OK"}
else
set theButtons to {"Copy to clipboard", "OK"}
end if
display alert "kMDItemWhereFroms info" message "The " & theMessage & "URL for " & aFile & " is: " & return & return & theURL buttons theButtons
if button returned of the result is not "OK" then set the clipboard to theURL
</pre>