Date Issue while creating Activity using BAPI_ACTIVITYCRM_CREATEMULTI

Question

Hi,
I'm creating an activity using BAPI BAPI_ACTIVITYCRM_CREATEMULTI and this is working fine. The only thing which is not reflecting in the activity is the date which I'm passing to this BAPI. The system  always puts the default date, which is system date.
Below are the parameters I'm passing in DATE and DATEX parameters of BAPI_ACTIVITYCRM_CREATEMULTI. Let me know if I'm doing something wrong.
Can someone help me? Any help in resolving this would be appreciated and rewarded with points. Thanks!
    lt_date-ref_handle = lt_header-handle. "handle for activity
    lt_date-ref_kind   = 'A'. "Adm header
    lt_date-appt_type  = 'ORDERACTUAL'. "Order actual date type
    lt_date-date_from  = '20060120'. "e.g.
    lt_date-time_from  = '1200000'. "e.g.
    lt_date-date_to    = '20060120'."e.g.
    lt_date-time_to    = '1200000'. "e.g.
    lt_date-show_local = 'X'.
    lt_date-mode       = 'A'."Create
    lt_datex-ref_handle = 'X'.
    lt_datex-ref_kind   = 'X'.
    lt_datex-appt_type  = 'X'.
    lt_datex-date_from  = 'X'.
    lt_datex-time_from  = 'X'.
    lt_datex-date_to    = 'X'.
    lt_datex-time_to    = 'X'.
    lt_datex-show_local = 'X'.
    lt_datex-mode      = 'X'.
    append: lt_date, lt_datex.
Regards,
Sandeep

Answer 1

Hi,
Here is a sample code for you.
*& Report  YAM_TEST_CONT_END_DATE                                      *
REPORT  yam_test_cont_end_date                  .
DATA: lit_header_guid TYPE crmt_object_guid_tab,
      lit_appointment TYPE crmt_appointment_comt,
      lit_status_comt TYPE crmt_status_comt,
      wa_status_comt  LIKE LINE OF lit_status_comt.
DATA : lit_ret          TYPE TABLE OF bapiret2,
       lit_obj_to_save  TYPE TABLE OF bapibus20001_guid_dis,
       lit_saved_obj    TYPE TABLE OF bapibus20001_object_id.
DATA: lv_header_guid   TYPE crmt_object_guid,
      lv_item_guid     TYPE crmt_object_guid,
      lv_timestamp(15) TYPE c.
DATA: lit_fname TYPE crmt_input_field_names_tab,
      wa_fname  TYPE crmt_input_field_names.
DATA: lit_input TYPE crmt_input_field_tab,
      wa_input  TYPE crmt_input_field.
DATA: wa_appointment      TYPE  crmt_appointment_com,
      wa_logical_date_key TYPE  crmt_date_logical_date_key.
CONSTANTS: lc_end       TYPE crmt_apptype     VALUE 'CONTEND',
           lc_appt      TYPE crmt_fieldname   VALUE 'APPT_TYPE',
           lc_from      TYPE crmt_fieldname   VALUE 'TIMESTAMP_FROM',
           lc_to        TYPE crmt_fieldname   VALUE 'TIMESTAMP_TO',
           lc_obj       TYPE crmt_object_name VALUE 'APPOINTMENT',
           lc_tzone_from(13) TYPE c           VALUE 'TIMEZONE_FROM',
           lc_tzone_to(11)   TYPE c           VALUE 'TIMEZONE_TO'.
PARAMETER: p_objid TYPE crmt_object_id.
START-OF-SELECTION.
* Get the HEADER GUID for the Contract Number
  SELECT SINGLE guid
    INTO lv_header_guid
    FROM crmd_orderadm_h
   WHERE object_id EQ p_objid.
  CHECK sy-subrc EQ 0.
* Get the Item GUID for the HEADER GUID
  SELECT SINGLE guid
    INTO lv_item_guid
    FROM crmd_orderadm_i
   WHERE header EQ lv_header_guid.
  CHECK sy-subrc EQ 0.
  APPEND lv_header_guid TO lit_header_guid.
  APPEND lv_header_guid TO lit_obj_to_save.
* Convert System date and time to timestamp
  CONCATENATE sy-datum sy-uzeit INTO lv_timestamp.
* Setting Contract End Date
  MOVE: lv_item_guid          TO wa_appointment-ref_guid,
        'B'                   TO wa_appointment-ref_kind,
        'CONTEND'             TO wa_appointment-appt_type,
        lv_timestamp          TO wa_appointment-timestamp_from,
        lv_timestamp          TO wa_appointment-timestamp_to,
        sy-zonlo              TO wa_appointment-timezone_to,
        sy-zonlo              TO wa_appointment-timezone_from.
* Filling the Input Fields for Appointment
  wa_fname-fieldname = lc_appt.
  INSERT wa_fname INTO TABLE lit_fname.
  CLEAR: wa_fname.
  wa_fname-fieldname = lc_from.
  INSERT wa_fname INTO TABLE lit_fname.
  CLEAR: wa_fname.
  wa_fname-fieldname = lc_to.
  INSERT wa_fname INTO TABLE lit_fname.
  CLEAR: wa_fname.
  wa_fname-fieldname = lc_tzone_from.
  INSERT wa_fname INTO TABLE lit_fname.
  CLEAR: wa_fname.
  wa_fname-fieldname = lc_tzone_to.
  INSERT wa_fname INTO TABLE lit_fname.
  CLEAR: wa_fname.
  wa_logical_date_key-appt_type = lc_end.
  MOVE: lv_item_guid          TO wa_input-ref_guid,
        'B'                   TO wa_input-ref_kind,
        lc_obj                TO wa_input-objectname,
        wa_logical_date_key   TO wa_input-logical_key,
        lit_fname             TO wa_input-field_names.
  APPEND wa_input TO lit_input.
  CLEAR: wa_input, wa_logical_date_key.
  APPEND wa_appointment TO lit_appointment.
  CALL FUNCTION 'CRM_ORDER_MAINTAIN'
    EXPORTING
      it_appointment    = lit_appointment
      it_status         = lit_status_comt
    CHANGING
      ct_input_fields   = lit_input
    EXCEPTIONS
      error_occurred    = 1
      document_locked   = 2
      no_change_allowed = 3
      no_authority      = 4
      OTHERS            = 5.
  CHECK sy-subrc EQ 0.
* Saving the items alone
  CALL FUNCTION 'BAPI_BUSPROCESSND_SAVE'
    TABLES
      objects_to_save = lit_obj_to_save
      saved_objects   = lit_saved_obj
      return          = lit_ret.
  CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
    EXPORTING
      wait = 'X'.
<b>Reward points if it helps.</b>
Regards,
Amit Mishra