Error in cast multiset in collections

Question

DECLARE
TYPE emp_dept_rec IS RECORD (
v_sal emp.sal%TYPE,
v_name emp.ename%TYPE,
v_deptname dept.DEPTNAME%type
TYPE emp_dept_tab_type IS TABLE OF emp_dept_rec;
l_emp_dept_tab emp_dept_tab_type;
type emp_tab is table of emp%rowtype;
type l_emp_tab is table of emp%rowtype;
type dept_tab is table of dept%rowtype;
type l_dept_tab is table of dept%rowtype;
cursor e1 is
select * from emp;
cursor d1 is select * from dept;
begin
OPEN e1;
FETCH e1
BULK COLLECT INTO l_emp_tab;
open d1;
FETCH d1
BULK COLLECT INTO l_dept_tab;
select cast(multiset (select em.sal,em,ename ,dep.DEPTNAME
from table(l_emp_tab) em,table(l_dept_tab) dep
where em.deptno=dep.deptno)
as emp_dept_tab_type)
into l_emp_dept_tab ;
end;
it is giving error as
ORA-06550: line 43, column 25:
PL/SQL: ORA-00923: FROM keyword not found where expected
ORA-06550: line 39, column 5:
PL/SQL: SQL Statement ignored

Answer 1

Here is an example.
SQL> CREATE OR REPLACE TYPE emp_rec IS OBJECT (
  2                      v_sal    NUMBER(7,2),
  3                      v_name   VARCHAR2(35),
  4                      v_empno  NUMBER(4),
  5                      v_deptno NUMBER(2)
  6                      )
  7  ;
  8  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_tab IS TABLE OF emp_rec;
  2  /
Type created.
SQL> CREATE OR REPLACE TYPE dept_rec IS OBJECT (
  2                      v_deptno NUMBER,
  3                      v_dname VARCHAR2(50)
  4                      )
  5  ;
  6  /
Type created.
SQL> CREATE OR REPLACE TYPE dept_tab IS TABLE OF dept_rec;
  2  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_dept_rec IS
  2                     OBJECT (
  3                      v_sal     NUMBER,
  4                      v_name     VARCHAR2(35),
  5                      v_deptname VARCHAR2(30)
  6                      );
  7  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_dept_tab_type IS TABLE OF emp_dept_rec;
  2  /
Type created.
SQL> set serverout on
SQL> DECLARE
  2    l_emp_dept_tab emp_dept_tab_type; --emp_dept_tab_type declared in database
  3    l_emp_tab      emp_tab; --emp_tab declared in database
  4    l_dept_tab     dept_tab; --dept_tab declared in database
  5 
  6    CURSOR e1 IS
  7      SELECT emp_rec(sal, ename, empno, deptno) FROM emp; --Note the type casting here
  8 
  9    CURSOR d1 IS
10      SELECT dept_rec(deptno, dname) FROM dept; --Note the type casting here
11  BEGIN
12    OPEN e1;
13 
14    FETCH e1 BULK COLLECT
15      INTO l_emp_tab;
16 
17    OPEN d1;
18 
19    FETCH d1 BULK COLLECT
20      INTO l_dept_tab;
21 
22    SELECT CAST(MULTISET (SELECT em.v_sal, em.v_name, dep.v_dname
23                   FROM TABLE(l_emp_tab) em, TABLE(l_dept_tab) dep
24                  WHERE em.v_deptno = dep.v_deptno) AS emp_dept_tab_type)
25      INTO l_emp_dept_tab
26      FROM DUAL;
27    FOR i IN 1 .. l_emp_dept_tab.COUNT LOOP
28      dbms_output.put_line(l_emp_dept_tab(i)
29                           .v_sal || '--' || l_emp_dept_tab(i)
30                           .v_name || '--' || l_emp_dept_tab(i).v_deptname);
31    END LOOP;
32 
33  END;
34  /
1300--MILLER--ACCOUNTING
5000--KING--ACCOUNTING
2450--CLARK--ACCOUNTING
3000--FORD--RESEARCH
1100--ADAMS--RESEARCH
3000--SCOTT--RESEARCH
2975--JONES--RESEARCH
800--SMITH--RESEARCH
950--JAMES--SALES
1500--TURNER--SALES
2850--BLAKE--SALES
1250--MARTIN--SALES
1250--WARD--SALES
1600--ALLEN--SALES
PL/SQL procedure successfully completed.It is just for educational purpose, because the thing you have achieved by so much programming can be done easily by simple join in the table itself.
user10447332 Newbie
Handle: user10447332
Status Level: Newbie
Registered: Oct 20, 2008
Total Posts: 227
Total Questions: 153 (152 unresolved) >
What a record! and most of the time you don't care to follow/revisit the thread also!.