Export import - using TOAD FOR ORACLE and ORACLE DATABASE 10G EXPRESS or s

Question

Hi all,
Could you please kindly help me?
I am using TOAD FOR ORACLE to export a table to flat file A. The tool just supports to distinguish fields by "spaces".
And the web page of ORACLE DATABASE 10G EXPRESS to import the data from flat file A to another database. To load data to a table from a text file, the web page bases on "comma" to distinguish fields.
So could you have any suggestion for me? I need to export data via TOAD FOR ORACLE. And then import it to another database by the home page of ORACLE DATABASE 10G EXPRESS or sqlplus.
Thank you so much for your help!

Answer 1

Dont use TOAD for exporting your data. Use PL/SQL. Below is the code given in Asktom.com that does what you want.
create or replace function  dump_csv( p_query     in varchar2,
                                      p_separator in varchar2 default ',',
                                      p_dir       in varchar2 ,
                                      p_filename  in varchar2 )
return number
is
    l_output        utl_file.file_type;
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(2000);
    l_status        integer;
    l_colCnt        number default 0;
    l_separator     varchar2(10) default '';
    l_cnt           number default 0;
begin
    l_output := utl_file.fopen( p_dir, p_filename, 'w' );
    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );
    for i in 1 .. 255 loop
        begin
            dbms_sql.define_column( l_theCursor, i, l_columnValue, 2000 );
            l_colCnt := i;
        exception
            when others then
                if ( sqlcode = -1007 ) then exit;
                else
                    raise;
                end if;
        end;
    end loop;
    dbms_sql.define_column( l_theCursor, 1, l_columnValue, 2000 );
    l_status := dbms_sql.execute(l_theCursor);
    loop
        exit when ( dbms_sql.fetch_rows(l_theCursor) <= 0 );
        l_separator := '';
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value( l_theCursor, i, l_columnValue );
            utl_file.put( l_output, l_separator || l_columnValue );
            l_separator := p_separator;
        end loop;
        utl_file.new_line( l_output );
        l_cnt := l_cnt+1;
    end loop;
    dbms_sql.close_cursor(l_theCursor);
    utl_file.fclose( l_output );
    return l_cnt;
end dump_csv;
/Here is the link to this thread in asktom.
http://asktom.oracle.com/pls/asktom/f?p=100:11:0::::P11_QUESTION_ID:95212348059