FFI wrapping Kernel32.dll

Question

PACKAGE BODY RER_UTILITY IS
/* Declare the library and function handles. */
kernel32_lhandle                Ora_Ffi.Libhandletype ;
computernamea_fhandle      Ora_Ffi.Funchandletype ;
/* Create the PL/SQL function that will actually */
/* invoke the foreign function. */
FUNCTION ff_computer_name(
     fhandle IN Ora_Ffi.Funchandletype,
strName IN OUT VARCHAR2,
lenName IN OUT NUMBER)RETURN NUMBER;
PRAGMA interface(C, ff_computer_name, 11265);
/* Create the PL/SQL function that is defined in */
/* the package spec. This function simply */
/* passes along the arguments it receives to */
/* ff_computer_name (defined above), prepending the */
/* foreign function handle to the argument List. */
PROCEDURE rer_computer_name(
     strName OUT VARCHAR2,
     lenName OUT NUMBER)
IS
          errNum     NUMBER;
BEGIN
     errNum := 1;
     MESSAGE('Before' || errNum);          
     errNum := ff_computer_name(computernamea_fhandle, strName, lenName);
MESSAGE('After' || errNum);          
EXCEPTION
     WHEN OTHERS THEN
          MESSAGE('Error: ' || SQLCODE || ' Desc: ' || SQLERRM);
          RAISE;     
END rer_computer_name;
/* Define the body of package RER_UTILITY */
BEGIN
     /* Load the library. */
     kernel32_lhandle := Ora_Ffi.Load_Library('C:\TEMP\', 'kernel32.dll');
     /* Register the foreign function. */
     computernamea_fhandle := Ora_Ffi.Register_Function(kernel32_lhandle, 'GetComputerNameA', Ora_Ffi.PASCAL_STD); -- Ora_Ffi.C_Std
     /* Register the return type. */
     Ora_Ffi.Register_Return(computernamea_fhandle, Ora_Ffi.C_LONG);
     /* Register both parameters of function GetComputerNameA. */
     Ora_Ffi.Register_Parameter(computernamea_fhandle, Ora_Ffi.C_CHAR);
     Ora_Ffi.Register_Parameter(computernamea_fhandle, Ora_Ffi.C_LONG);
EXCEPTION
          WHEN OTHERS THEN
          MESSAGE('Error: ' || SQLCODE || ' Desc: ' || SQLERRM);
          RAISE;
END; /* Package Body RER_UTILITY */
Forms 6i running on a XP Pro box pointing toward an 8i database.
Running the code will kick me out with no error.
Running in debug mode, I get a ORA-304500 error.
Any ideas?
Much thanks!

Answer 1

1. You can use the D2KWUTIL library to get the computer name. There is
the WIN_API_ENVIRONMENT.Get_Computer_Name function there.
2. I believe the following code works too:
---- cut here ----
PACKAGE BODY W IS
kernel32_lhandle Ora_Ffi.Libhandletype;
GetComputerName_fhandle Ora_Ffi.Funchandletype;
FUNCTION ff_GetComputerName(
fhandle Ora_Ffi.Funchandletype,
lbBuffer varchar2,
nSize pls_integer ) RETURN pls_integer;
PRAGMA interface(C, ff_GetComputerName, 11265);
FUNCTION GetComputerName RETURN varchar2 IS
buf varchar2(1000);
nSize pls_integer;
ret pls_integer;
BEGIN
-- You have to initialize the buffer for a received information
-- before you call the WinAPI function
-- Allocates 1000 bytes for the buffer
buf:=RPAD( '*', 1000, '*' );
nSize:=length(buf)-1;
ret:=ff_GetComputerName( GetComputerName_fhandle, buf, nSize );
if ret=0 then
-- If the function fails, the return value is zero.
return NULL;
end if;
return substr( buf, 1, nSize );
END;
PROCEDURE Init IS
BEGIN
-- Load the library.
kernel32_lhandle := Ora_Ffi.Load_Library( '', 'kernel32.dll' );     
-- BOOL GetComputerName(
-- LPTSTR lpBuffer, // address of name buffer
-- LPDWORD nSize // address of size of name buffer
GetComputerName_fhandle := Ora_Ffi.Register_Function(
kernel32_lhandle,
'GetComputerNameA',
Ora_Ffi.C_Std );
Ora_Ffi.Register_Parameter( GetComputerName_fhandle, Ora_Ffi.C_CHAR_PTR );
Ora_Ffi.Register_Parameter( GetComputerName_fhandle, Ora_Ffi.C_INT_PTR );
Ora_Ffi.Register_Return( GetComputerName_fhandle, Ora_Ffi.C_INT );
END;
BEGIN
Init;
END;
---- cut here ----