Help with Collections and Reference Cursor

Question

I have a procedure where I want to populate a table type and then return the results with a reference cursor so the results can be used by Hyperion. Here are the type declarations:
create or replace type gg_audit_object as object (
               owner varchar2(30),
               table_name varchar2(30),
               lag_time number)
CREATE OR REPLACE TYPE gg_audit_table AS TABLE OF gg_audit_object
and here's the procedure:
CREATE OR REPLACE PROCEDURE ETSREP_GG_AUDIT_XX2 (results_cursor in out types.cursorType)
AS
v_owner varchar2(30);
v_table_name varchar2(30);
v_column_name varchar2(30);
type v_record is record(
owner varchar2(30),
table_name varchar2(30),
lag_time number);
r1 v_record;
t1 gg_audit_table;
table_cr types.cursorType;
sql_stmt varchar2(5000);
cursor table_select is
select g.owner,
g.table_name,
g.column_name
from gg_tables_to_audit g
where g.active_ind = 'Y'
order by 1,2;
BEGIN
rec_count := 0;
for main_rec in table_select loop
sql_stmt := '';
v_owner := main_rec.owner;
v_table_name := main_rec.table_name;
v_column_name := main_rec.column_name;
sql_stmt := 'select '
|| '''' || v_owner || ''','
|| '''' || v_table_name || ''','
|| 'sysdate - max(' || v_column_name || ') '
|| 'from ' || v_owner || '.' || v_table_name;
open table_cr for sql_stmt;
FETCH table_cr into r1;
close table_cr;
-- here's where I'm stumped. I need to take the values from r1 and put them
-- into t1.
-- Something like this (or whatever is the correct way to do it)
-- insert into table(t1) values (r1.owner, r1.table_name, r1.lag_time);
end loop; -- end table_select loop
-- and then open a reference cursor and select them out of t1.
-- Something like
-- open results_cursor for select * from t1;
END;
Just trying to avoid creating a real table and populating that. Any guidance would be greatly appreciated.

Answer 1

Found the perfect example on Ask Tom. Here is the solution.
create or replace package GG_AUDIT
as
type rc is ref cursor;
procedure GG_AUDIT_PROC( r_cursor in out types.cursorType );
end;
create or replace package body GG_AUDIT
as
procedure GG_AUDIT_PROC( r_cursor in out types.cursorType )
is
l_data gg_audit_table := gg_audit_table();
table_cr types.cursorType;
type v_record is record(
owner varchar2(30),
table_name varchar2(30),
lag_time number);
r1 v_record;
sql_stmt varchar2(5000);
v_owner varchar2(30);
v_table_name varchar2(30);
v_column_name varchar2(30);
rec_count number := 0;
cursor table_select is
select g.owner,
g.table_name,
g.column_name
from gg_tables_to_audit g
where g.active_ind = 'Y'
order by 1,2;
begin
for main_rec in table_select loop
sql_stmt := '';
v_owner := main_rec.owner;
v_table_name := main_rec.table_name;
v_column_name := main_rec.column_name;
sql_stmt := 'select '
|| '''' || v_owner || ''','
|| '''' || v_table_name || ''','
|| 'sysdate - max(' || v_column_name || ') '
|| 'from ' || v_owner || '.' || v_table_name;
open table_cr for sql_stmt;
FETCH table_cr into r1.owner, r1.table_name, r1.lag_time;
close table_cr;
rec_count := rec_count + 1;
l_data.extend;
l_data(rec_count) := gg_audit_object(r1.owner, r1.table_name, r1.lag_time);
end loop;
open r_cursor for select * from TABLE ( cast ( l_data as gg_audit_table) );
end; -- end procedure
end;
Works perfectly. Thanks guys.