Help with Difficult Sorting Task - Script Inside

Question

Hello,
I have a very time consuming task that I would like to adjust the script below to help cut down the labor. The script below, will ask for a root folder and will copy all the folders inside that root folder to a secondary location. It will only copy the folders and not the files inside them. This works great. But my next step is to manually drag and drop the ".cos" files from the "master drive" from each shot folder to the emtpy "Settings50" folder that has been duplicated to my desktop. Is it possible in any way, to first copy the whole folder structure, and then only copy the "Settings50" folder and the files inside them to the secondary location? The image attached shows what I need duplicated in green and what I do not want duplicated in red. The reason I cannot simply copy the whole root folder is because the RAW files in red are very very large and takes forever to copy. I ONLY need the folder structure duplicated with the Settings50 folder copied with files inside them to a secondary location. If you can help out I would very very much apprecieate it!
on run
          set source_folder to choose folder with prompt "Select folder to be duplicated:" as string
          my do_main_script(source_folder)
end run
on open of source_folder_list
          repeat with i from 1 to number of items in the source_folder_list
                    set this_folder_path to item i of the source_folder_list as string
                    if last character of this_folder_path is ":" then
                              my do_main_script(this_folder_path)
                    end if
          end repeat
end open
on do_main_script(source_folder)
          tell application "Finder" to set source_folder to folder (source_folder)
          set the target_folder to (choose folder with prompt "Where would you like the duplicated folders to be moved to?")
          if source_folder is not "" and target_folder is not "" then
                    set new_folder_name to (name of source_folder as string) & " duplicate"
                    set source_folder to source_folder as string
                    set target_folder to target_folder as string
                    my create_new_folder(target_folder, new_folder_name)
                    my duplicate_folder_structure(source_folder, target_folder & new_folder_name & ":")
          end if
end do_main_script
on duplicate_folder_structure(source_folder, target_folder)
          tell application "Finder"
                    try
                              get name of folders of folder (source_folder)
                              set folder_list to result
                              repeat with i from 1 to number of items in the folder_list
                                        set this_folder_name to item i of the folder_list as string
                                        my create_new_folder(target_folder, this_folder_name)
                                        my duplicate_folder_structure(source_folder & this_folder_name & ":", target_folder & this_folder_name & ":")
                              end repeat
                    end try
          end tell
end duplicate_folder_structure
on create_new_folder(target_folder, new_folder_name)
          tell application "Finder"
                    try
                              if not (exists item (target_folder & new_folder_name)) then
  make new folder at folder target_folder with properties {name:new_folder_name}
                              end if
                    end try
          end tell
end create_new_folder
Thanks!
Anthony

Answer 1

Well, I think this will be close.  test it and see what needs to be improved.
on run
          set source_folder to choose folder with prompt "Select folder to be duplicated:" as string
          my do_main_script(source_folder)
end run
on open of source_folder_list
          repeat with this_item in the source_folder_list
                    if last character of (this_item as string) is ":" then
                              my do_main_script(this_item as string)
                    end if
          end repeat
end open
on do_main_script(source_folder)
          set the target_folder to (choose folder with prompt "Where would you like the duplicated folders to be moved to?")
          if source_folder is not "" and target_folder is not "" then
                    tell application "System Events" to set new_folder_name to (name of source_folder) & " duplicate"
                    set new_folder to checkForFolder(target_folder as string, new_folder_name)
  duplicate_folder_structure(source_folder as string, new_folder)
          end if
end do_main_script
on duplicate_folder_structure(source_folder, target_folder)
          tell application "System Events"
                    set folder_list to folders of folder source_folder
                    repeat with this_folder in the folder_list
                              set this_folder_name to name of this_folder
                              set new_folder to my checkForFolder(target_folder as string, this_folder_name)
                              my duplicate_folder_structure(path of this_folder, new_folder)
                    end repeat
          end tell
          tell application "Finder"
                    set cos_file_list to every file of folder source_folder whose name ends with ".cos"
  duplicate cos_file_list to target_folder
          end tell
end duplicate_folder_structure
to checkForFolder(fParent, fName)
          tell application "System Events"
                    if not (exists folder fName of folder fParent) then
                              set output to path of (make new folder at end of folder fParent with properties {name:fName})
                    else
                              set output to (path of (folder fName of folder fParent))
                    end if
          end tell
          return alias output
end checkForFolder