How do your sort input numbers horizontally in the same field "6-4-25-23-11-45" ms access 2010

Question

Hi,
Is there a function to sort numbers horizontally in ms access 2010.
Regards,
Rudolf
rudolfelizabeth

Answer 1

Copy the following code into a module in the Visual Basic Editor:
Function SortValues(varText As Variant, strSep As String) As Variant
Dim arr() As String
If IsNull(varText) Then
SortValues = Null
Else
arr = Split(varText, strSep)
SortArray arr
SortValues = Join(arr, strSep)
End If
End Function
Sub SortArray(arr() As String)
Dim i As Long
Dim j As Long
Dim lngTemp As Long
For i = LBound(arr) To UBound(arr) - 1
For j = i + 1 To UBound(arr)
If CLng(arr(i)) > CLng(arr(j)) Then
lngTemp = arr(i)
arr(i) = arr(j)
arr(j) = lngTemp
End If
Next j
Next i
End Sub
Let's say your field is named MyField. In a query, you can create a calculated column:
MySortedField: SortValues([MyField],"-")
Or you can set the Control Source of a text box on a form or report to
=SortValues([MyField],"-")
Regards, Hans Vogelaar (http://www.eileenslounge.com)