How to Extract top most position in any given Org Unit

Question

Hi Experts,
I have  a requirement to extract the highest position(or root position) in any given OrgUnit.  See the below example for more info.
Eg: org1
       -- position1
    Org2
         -- position2   
    Org3
       --Org3A
          -- position3
       --Org3B
          -- position4
As shown in the above structure, I need to extract the top most position in each Orgunit structure like postion1, position2, position3 and position4.  Note that Org3 does not have a immediate position or chief position so we are reading position3 and 4 instead for org3.
Thanks in Advance,
Vijay

Answer 1

The best way is to search until there is no more, in order to create the hierarchy.
To get all the B002 relationships for a respective Org. use parameter ACT_TDEPTH = 99 (i guess it won't go that deep) for the top Org.
The output table RESULT_STRUC will have a hierarchy structure, with all organizational units below the top one. Use the fields LEVEL and PDOWN (or PUP) to construct the hierarchy. Then for each ORG. just search for the manager position (B012).
Just a small look-in to what the fields in that table mean :
LEVEL - Level of the Org.
SEQNR - Index of ORG.
PDOWN - SEQNR of ORG below.
VCOUNT - Number of "brothers" (Orgs at the same level)
PNEXT - Brother to the RIGHT
PUP - Father
PPREV - Brother to the Left
Here is a sample program i made to insert this into a table that will later be used for creating an ALVTREE as an F4 for a field.
REPORT  YHR00101UPDPG.
* TABELAS
TABLES: HRP1000, HRP1001.
* VARIAVEIS AUXILIARES
DATA: T_STRUC TYPE TABLE OF STRUC,
      WA_STRUC TYPE STRUC,
      WA_YTHR00035 TYPE YTHR00035.
DATA: W_PLVAR type OBJEC-PLVAR.
DATA: W_OBJID TYPE HRP1000-OBJID.
* ECRAN DE SELECCAO
SELECTION-SCREEN : BEGIN OF BLOCK bloco1 WITH FRAME TITLE text-001.
PARAMETERS : P_objid type hrp1000-objid MATCHCODE OBJECT PLOMA,
             P_begda type hrp1000-begda DEFAULT sy-datum.
SELECTION-SCREEN END OF BLOCK bloco1.
START-OF-SELECTION.
* Get plan variant
  call function 'RH_GET_ACTIVE_WF_PLVAR'
       importing
            act_plvar = w_plvar
       exceptions
            others    = 1.
  CALL FUNCTION 'RH_STRUC_GET'
    EXPORTING
      ACT_OTYPE              = 'O'
      ACT_OBJID              = p_objid
      ACT_WEGID              = 'B002'
      ACT_PLVAR              = w_plvar
      ACT_BEGDA              = p_begda
      ACT_ENDDA              = p_begda
      ACT_TDEPTH             = 99
      ACT_TFLAG              = 'X'
      ACT_VFLAG              = 'X'
      AUTHORITY_CHECK        = 'X'
    TABLES
      RESULT_STRUC           = T_STRUC
    EXCEPTIONS
      NO_PLVAR_FOUND         = 1
      NO_ENTRY_FOUND         = 2
      OTHERS                 = 3.
  IF SY-SUBRC <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  if not t_struc[] is initial.
    delete from YTHR00035.
  endif.
* Agora temos a estrutura vamos criar a tabela YTHR00035
  LOOP AT T_STRUC INTO WA_STRUC.
    clear WA_YTHR00035.
    WA_YTHR00035-NIVEL          = WA_STRUC-LEVEL.
    WA_YTHR00035-SEQNR          = WA_STRUC-SEQNR.
    WA_YTHR00035-ORGID          = WA_STRUC-OBJID+0(8).
    WA_YTHR00035-FILHO          = WA_STRUC-PDOWN.
    WA_YTHR00035-NR_IRMAOS      = WA_STRUC-VCOUNT.
    WA_YTHR00035-IRMAO_DIREITA  = WA_STRUC-PNEXT.
    WA_YTHR00035-PAI            = WA_STRUC-PUP.
    WA_YTHR00035-IRMAO_ESQUERDA = WA_STRUC-PPREV.
* Primeiro vamos buscar a descrição da Unidade Organizacional
    select single MC_STEXT into WA_YTHR00035-NMORG from HRP1000 where
      PLVAR = w_plvar and
      OTYPE = 'O' and
      OBJID = WA_YTHR00035-ORGID and
      BEGDA <= p_begda and
      endda >= p_begda.
    clear hrp1001.
* Aqui verificamos se a Un. Organizacional tem uma posição de chefia associada
    select single * from HRP1001 where
      plvar = w_plvar and
      OTYPE = 'O' and
      ISTAT = '1' and
      OBJID = WA_YTHR00035-ORGID and
      RSIGN = 'B' and
      RELAT = '012' and
      BEGDA <= p_begda and
      endda >= p_begda.
    if sy-subrc = 0.
* Encontramos uma ligação com uma posição de chefia
      WA_YTHR00035-POSID = HRP1001-SOBID+0(8).
* Primeiro vamos buscar a descrição da Unidade Organizacional
      select single MC_STEXT into WA_YTHR00035-NMPOS from HRP1000 where
        PLVAR = w_plvar and
        OTYPE = 'S' and
        OBJID = WA_YTHR00035-POSID and
        BEGDA <= p_begda and
        endda >= p_begda.
    endif.
    INSERT YTHR00035 FROM WA_YTHR00035.
  ENDLOOP.
  commit work.
END-OF-SELECTION.
Hope this helps.
Edited by: Pedro Guarita on Dec 16, 2010 2:30 PM