How to get spool number when using SUBMIT job

Question

Hi All,
I am calling standard program using SUBMIT through JOB as below. Now I need spool number for this job to covert the output to PDF and send to mail. See the below code and guide me.
CALL FUNCTION 'JOB_OPEN'
  EXPORTING
    jobname          = name
  IMPORTING
    jobcount         = number
  EXCEPTIONS
    cant_create_job  = 1
    invalid_job_data = 2
    jobname_missing  = 3
    OTHERS           = 4.
IF sy-subrc = 0.
  data: Zscreen type table of RSPARAMS with header line.
   Zscreen-selname = 'PM_AENNR'.
   Zscreen-kind = 'P'.
   ZSCREEN-LOW = '500000000125'.
   APPEND ZSCREEN.
SUBMIT RCC00130 WITH selection-table Zscreen TO SAP-SPOOL
                    SPOOL PARAMETERS print_parameters
                   WITHOUT SPOOL DYNPRO
                    VIA JOB name NUMBER number
                    AND RETURN.
  IF sy-subrc = 0.
    CALL FUNCTION 'JOB_CLOSE'
      EXPORTING
        jobcount             = number
        jobname              = name
        strtimmed            = 'X'
      EXCEPTIONS
        cant_start_immediate = 1
        invalid_startdate    = 2
        jobname_missing      = 3
        job_close_failed     = 4
        job_nosteps          = 5

Answer 1

Hi,
Do this way, first get print parameters by using function module 'GET_PRINT_PARAMETERS'
CALL FUNCTION 'GET_PRINT_PARAMETERS'
    EXPORTING
      destination    = 'LP01'
      list_name      = 'TEST'
      list_text      = 'SUBMIT ... TO SAP-SPOOL'
      immediately    = ' '
      line_size      = '1023'
      no_dialog      = 'X'
    IMPORTING
      out_parameters = wa_pri_params
      valid          = w_valid.
If it returns success then
    IF w_valid EQ 'X'.
      CONCATENATE 'R'                                   
                   w_tabix                                
                   sy-datum+4(4)
                   sy-uzeit INTO
                   wa_pri_params-plist.
    ENDIF.
    SUBMIT rprccc00
           WITH firmennr = w_cid
           WITH bel_clus = 'X'
           WITH testlauf = ' '
           WITH not_lokl = 'X'
           WITH file_in  = w_arc_out
           TO SAP-SPOOL WITHOUT SPOOL DYNPRO
           SPOOL PARAMETERS wa_pri_params AND RETURN.
    COMMIT WORK AND WAIT.
SELECT rqident
         FROM tsp01
         INTO w_rqident
         UP TO 1 ROWS
         WHERE rq2name = wa_pri_params-plist.
  ENDSELECT.
CALL FUNCTION 'CONVERT_ABAPSPOOLJOB_2_PDF'
    EXPORTING
      src_spoolid     = w_rqident
      no_dialog       = 'X'
      dst_device      = 'LP01'
      pdf_destination = 'X'
    TABLES
      pdf             = t_pdf.
Hope it solves your problem
Regards
Krishna