Inserting a Text Box? - Applescript

Question

Thanks for helping me out earlier. Now I want to insert a text box at the bottom of the page 4.5 inches wide and .5 inches tall, how do I script that in?
This is all needed as part of a workflow I am doing with automator, and once I can solve that, then I am DONE!
Here is my apple script:
tell application "Microsoft Word"
  activate
          set orientation of page setup of section 1 of active document to orient landscape
          set mar to page setup of active document
          set left margin of mar to (inches to points inches 1)
          set right margin of mar to (inches to points inches 1)
          set top margin of mar to (inches to points inches 0.7)
          set bottom margin of mar to (inches to points inches 1.5)
          set alignment of paragraphs of active document to align paragraph center
end tell
Thanks.

Answer 1

Hi,
Here is an example :
tell application "Microsoft Word"
      activate
      tell active document
            set orientation of page setup of section 1 to orient landscape
            tell its page setup
                  set pWidth to page width
                  set lMargin to inches to points inches 1
                  set left margin to lMargin
                  set right margin to lMargin
                  set top margin to (inches to points inches 0.7)
                  set bottom margin to (inches to points inches 1.5)
            end tell
            set alignment of paragraphs to align paragraph center
            set nP to (count paragraph)
            -- the doc must have at least two blank paragraphs at end of it before creating the textbox
            if (content of text object of paragraph (nP - 1)) is not return then insert paragraph at after last character
            if (content of text object of paragraph nP) is not return then insert paragraph at after last character
            select text object of last paragraph -- select the last blank paragraph
      end tell
      create textbox selection
      tell last text box of active document
            set height to inches to points inches 0.5
            set width to inches to points inches 4.5
            set content of text range of its text frame to "something" -- set the content of this text box
            set left position to ((pWidth / 2) - (width / 2)) - lMargin -- center the text box, no center alignment in AppleScript
      end tell
end tell