Intel iMac not reading time correctly

Question

G'day
This is pretty desperate. I've got a 3000+ line applescript that automates a mail room for a large company.
They want to buy an intel iMac to exclusively run the script, but the script uses time based files for error reporting.
On my intel iMac the files read as 1st January 1904 12.00.00 am not matter what I do.
Are Apple fixing this, or is there a workaround?
Regards, Santa

Answer 1

Thanks red_menace. The test script I ended up with is as follows...
my Timer()
my displayInfo()
on Timer()
copy (current date) - (time to GMT) to tempDate
-- For universal time
copy tempDate to KeepTheTime
-- For an invisible file, put a full stop in front of the name ie ".Timer"
set t to my ReadTheTime("Timer", KeepTheTime)
display dialog "elapsed : " & my setTheDaysHoursMinutesSeconds(KeepTheTime - t) buttons {"OK", "See elapsed time", "Reset Timer"}
set temp to button returned of the result
if temp = "Reset Timer" then
copy (current date) - (time to GMT) to tempDate -- For universal time
my SaveTheTime("Timer", tempDate)
my Timer()
else
if temp = "See elapsed time" then my Timer()
end if
end Timer
on displayInfo()
copy (current date) - (time to GMT) to tempDate -- For universal time
copy tempDate to KeepTheTime
set time of tempDate to 0
set dayelapsedtime to KeepTheTime - tempDate
set day of tempDate to 1
set monthelapsedtime to KeepTheTime - tempDate
set month of tempDate to 1
set yearlyelapsedtime to KeepTheTime - tempDate
display dialog "Universal time" & return & return & ¬
"Since midnight, " & dayelapsedtime & " seconds have elapsed." & return & my setTheDaysHoursMinutesSeconds(dayelapsedtime) & return & return & ¬
"Since 12.00 am on the first of the month, " & monthelapsedtime & " seconds have elapsed." & return & my setTheDaysHoursMinutesSeconds(monthelapsedtime) & return & return & ¬
"Since 12.00 am January 1, " & yearlyelapsedtime & " seconds have elapsed." & return & my setTheDaysHoursMinutesSeconds(yearlyelapsedtime) buttons {"OK", "Refresh information"}
if button returned of the result = "Refresh information" then my displayInfo()
end displayInfo
on ReadTheTime(Filename, KeepTheTime)
tell application "Finder"
set TheFileName to (path to desktop folder as string) & Filename
try
set theSavedTime to (read file TheFileName as «class isot») as date
return theSavedTime
on error
my SaveTheTime(Filename, KeepTheTime)
return KeepTheTime
end try
end tell
end ReadTheTime
on SaveTheTime(Filename, KeepTheTime)
tell application "Finder"
set TheFileName to (path to desktop folder as string) & Filename
end tell
set fRef to (open for access file TheFileName with write permission)
set eof fRef to 0
try
set KeepTheTime to KeepTheTime as «class isot»
write KeepTheTime to fRef
end try
close access fRef
end SaveTheTime
on setTheDaysHoursMinutesSeconds(theSeconds)
set TheTotalDays to theSeconds div days
set TheTotalHours to (theSeconds - (TheTotalDays * days)) div hours
set thetotalminutes to (theSeconds - ((TheTotalDays * days) + (TheTotalHours * hours))) div minutes
set theTotalSeconds to theSeconds - ((TheTotalDays * days) + (TheTotalHours * hours) + (thetotalminutes * minutes))
set the AnswerString to ""
if TheTotalDays > 0 then set the AnswerString to the AnswerString & TheTotalDays & " Days "
if TheTotalHours > 0 then set the AnswerString to the AnswerString & TheTotalHours & " Hours "
if thetotalminutes > 0 then set the AnswerString to the AnswerString & thetotalminutes & " Minutes "
set the AnswerString to the AnswerString & theTotalSeconds & " Seconds."
return the AnswerString
end setTheDaysHoursMinutesSeconds