Is it possible send several interactives forms in one only email?

Question

Hi again experts!
I would like to know if is it possible attach many interactives forms in one mail.
In order to do personnel evaluation we send an  e mail to Departement Manangers attaching an interactive form for every employee in his or her Department.
I'd like send only one email for every manager.
Do you think is it possible?
If yes, some idea?
Thank you very much,
Gloria

Answer 1

Hi gloria,
Yes it's possible to do it .
When you create an e-mail with BCS functionnality you can add several attachment to it .
Here is a sample code for this .
Best regards.
Bertrand
TYPE-POOLS : abap .
DATA : data_for_update TYPE zdemopdf ,
       hexa            TYPE solix_tab.
DATA : fm_name   TYPE funcname ,
       param     TYPE sfpoutputparams,
       doc_param TYPE sfpdocparams ,
       output    TYPE fpformoutput .
** CLASS-DEFINITIONS
DATA: send_request       TYPE REF TO cl_bcs.
DATA: document           TYPE REF TO cl_document_bcs.
*DATA: sender             TYPE REF TO cl_sapuser_bcs.
data: sender            TYPE REF TO if_sender_bcs.
DATA: recipient          TYPE REF TO if_recipient_bcs.
** INTERNAL TABLES
DATA: l_mailtext TYPE soli_tab.
DATA: iaddsmtp   TYPE TABLE OF bapiadsmtp.
DATA: ireturn    TYPE TABLE OF bapiret2.
** VARIABLES
DATA: mail_line  LIKE LINE OF l_mailtext.
DATA: bapiadsmtp         TYPE bapiadsmtp.
DATA: subject    TYPE so_obj_des.
DATA : att_subject TYPE so_obj_des.
DATA : w_except TYPE REF TO cx_root .
FIELD-SYMBOLS : <smtp> TYPE bapiadsmtp.
param-nodialog = abap_true. " suppress printer dialog popup
param-getpdf = abap_true.
doc_param-langu = sy-langu.
doc_param-country = 'FR'.
doc_param-fillable = abap_true.
doc_param-dynamic = abap_true.
CALL FUNCTION 'FP_FUNCTION_MODULE_NAME'
  EXPORTING
    i_name     = 'ZDEMO_PDF'
  IMPORTING
    e_funcname = fm_name.
*Set subject of the mail
subject = 'Sample Mail with several forms'.
* Set text of the mail
mail_line = 'here it is'.
APPEND mail_line TO l_mailtext .
* Set attachment name
att_subject = 'Sample form'.
TRY.
* Create persistent send request
    send_request = cl_bcs=>create_persistent( ).
* Get sender object
    sender = cl_sapuser_bcs=>create( sy-uname ).
* Add sender
    CALL METHOD send_request->set_sender
      EXPORTING
        i_sender = sender.
* Create the Recipient
        recipient =
     cl_cam_address_bcs=>create_internet_address( ****** ). " Set the e-mail adress of the recipient
* Add recipient with its respective attributes to send request
    CALL METHOD send_request->add_recipient
      EXPORTING
        i_recipient  = recipient
        i_express    = 'X'
        i_copy       = space
        i_blind_copy = space
        i_no_forward = space.
* Set that you don't need a Return Status E-mail
    CALL METHOD send_request->set_status_attributes
      EXPORTING
        i_requested_status = 'E'
        i_status_mail      = 'E'.
* set send immediately flag
    send_request->set_send_immediately( 'X' ).
*Build Document
    document = cl_document_bcs=>create_document(
                        i_type    = 'RAW'
                        i_text    = l_mailtext
                        i_subject = subject ).
*     add attachment to document
do 5 times.
CALL FUNCTION 'FP_JOB_OPEN'
  CHANGING
    ie_outputparams = param
  EXCEPTIONS
    cancel          = 1
    usage_error     = 2
    system_error    = 3
    internal_error  = 4.
CHECK sy-subrc EQ 0.
CALL FUNCTION fm_name
  EXPORTING
    /1bcdwb/docparams  = doc_param
    data_for_update    = data_for_update
  IMPORTING
    /1bcdwb/formoutput = output
  EXCEPTIONS
    usage_error        = 1
    system_error       = 2
    internal_error     = 3.
CALL FUNCTION 'FP_JOB_CLOSE'
  EXCEPTIONS
    usage_error    = 1
    system_error   = 2
    internal_error = 3
    OTHERS         = 4.
CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
  EXPORTING
    buffer     = output-pdf "PDF file from function module
  TABLES
    binary_tab = hexa.
    CALL METHOD document->add_attachment
      EXPORTING
        i_attachment_type    = 'PDF'
        i_attachment_subject = att_subject
        i_att_content_hex    = hexa.
* Add document to send request
    CALL METHOD send_request->set_document( document ).
enddo.
* Send document
    CALL METHOD send_request->send( ).
    COMMIT WORK.
  CATCH cx_send_req_bcs INTO w_except.
  CATCH cx_address_bcs INTO w_except.
  CATCH cx_document_bcs INTO w_except.
ENDTRY.