Pages 5.0 - Status bar current page & page count?

Question

How do I show the status bar showing current page and page count? I do not need to see the full thumbnail bar.
In all prior versions of pages, I could look at the bottom of my window and see my current page and how many pages are in my document.  Now, I glance to the bottom, and I have no idea.  I cannot find any way to turn this on and turning on the thumbnails view does not show this to me at-a-glance because I have to scroll all the way down (through documents hundreds of pages long) to find out how many pages I currently have.
Please, what am I missing here, how can I make this show up again?
I mean a quick display here, not adding the page count and numbers to a documents footer.  Although, that would be one way for me to solve this issue, but I do not always want that.

Answer 1

I wrote a short AppleScript solution that informs about the current document page as a pop-up dialog. This is for Pages v5+ only. I created and saved an Automator Application named CurrentPage to my Desktop. Providing that Pages is running, it will produce the dialog shown in subsequent Automator screen shot.
Double-click /Applications/Automator and choose New Document, Application, and Choose. Follow the Utilities > Run AppleScript (not Shell Script as shown), and drag Run AppleScript over into the larger window and drop it. Select all of its contents and remove them -- this is just boilerplate.
Copy and paste the following AppleScript into the now vacant Run AppleScript workflow window. Click the hammer, and File > Save... pick a name, and location to save the application where it is handy. Quit Automator.
Code:
-- P
-- Produce formatted dialog of document name, current page, and page count
-- Pages v5+ only. Works whether typing in document or scrolling pages.
-- VikingOSX, June 2014, Apple Support Community - Pages for Mac.
if not ApplicationIsRunning("Pages") then
  display dialog "Pages must be running to use this utility."
  return quit
end if
tell application "Pages"
  activate
  tell front document
  set diagTitle to "Current Document Page"
  set docName to (name as text)
  set thePage to current page
  set curPage to 0
  set pageCnt to page count
  set pnList to its page
  repeat with ndx from 1 to count of pnList
  if thePage is equal to item ndx of pnList then
  set curPage to ndx
  end if
  end repeat
  set vformat to "Document: " & tab & tab & docName & return ¬
  & "Current Page: " & tab & curPage & return ¬
  & "Total Pages: " & tab & tab & pageCnt
  end tell
end tell
display dialog (vformat as text) giving up after 15 with title diagTitle
on ApplicationIsRunning(appName)
  tell application "System Events" to set appNameIsRunning to exists (processes where name is appName)
  return appNameIsRunning
end ApplicationIsRunning