Sales order item First Date

Question

Hi all,
when ever customer changes the first date they need a pop saying the date has been modified please check it.
can any one tell me when ever SO item level first date is changed any user-exit available to POP-UP the message.
Regards,
Abdul gaffar.

Answer 1

Hello Abdul,
In the below sample coding we compare first date from VBEP in databse with the changed first date on screen.
It is a better idea to put the below coding in a separate INCLUDE and include it inside the userexit_check_vbap form. That way MV45AFZB will have less coding clutter and also in future only the include needs to be changed without needing to lock MV45AFZB (so that more than one project can work on changes to MV45AFZB).
Also remember that popups break BDC's and background jobs, so any popups that you show during sales order processing should also contain checks so that they only trigger in foreground mode with dialog users (sy-batch IS INITIAL - not background job AND sy-binpt IS INITIAL - not batch input  AND usr02-ustyp = 'A' - only dialog user AND rv45a-docnum IS INITIAL - order not created through IDoc)
  DATA: lv_edatu TYPE vbep-edatu,
        lv_ustyp TYPE usr02-ustyp.
* Sales document is in change mode
  IF t180-trtyp = charv.
* Get the user type
    SELECT SINGLE ustyp INTO lv_ustyp
      FROM usr02
        WHERE bname = sy-uname.
* Trigger the popup for only dialog user during online processing
    IF sy-batch IS INITIAL AND sy-binpt IS INITIAL AND lv_ustyp = 'A' AND rv45a-docnum IS INITIAL.
* Get first date from database
      SELECT SINGLE edatu INTO lv_edatu
      FROM vbep
         WHERE vbep~vbeln = vbap-vbeln AND
               vbep~posnr = vbap-posnr AND
               vbep~etenr = '0001'.
* Retrieve the first schedule line from screen that is not deleted
      CLEAR ls_xvbep.
      LOOP AT xvbep INTO ls_xvbep
        WHERE vbeln = vbap-vbeln AND
              posnr = vbap-posnr AND
              etenr = '0001' AND
              updkz NE chard.
        EXIT.
      ENDLOOP.
* If screen first date different from first date in databse show popup
      IF lv_edatu NE ls_xvbep-edatu.
       "Show popup
      ENDIF.
    ENDIF.
  ENDIF.
To the above poster, it is not better to user userexit_save_document_prepare as this is triggered only during save and many items may have changed. userexit_check_vbap on the other hand triggers for each item that is changed, then and there.
Best regards,
Vishnu Tallapragada