Use of ROW_NUMBER() function in PL/SQL

Question

I have a Table Emp with the following Structure
SQL> desc emp
Name Null? Type
EMPNO NUMBER(2)
ENAME VARCHAR2(50)
HIREDATE DATE
DEPTNO NUMBER(2)
If I write a following query on this table
SQL> SELECT deptno, hiredate, record_id
2 FROM (SELECT deptno, ename, hiredate, ROW_NUMBER()
3 OVER (ORDER BY hiredate) AS record_id
4 FROM emp)
5 WHERE record_id >= 2
6 AND record_id <=5;
The Result I get is
DEPTNO HIREDATE RECORD_ID
10 22-NOV-01 2
10 22-NOV-01 3
10 22-NOV-01 4
10 22-NOV-01 5
But if I put this query in a cursor in a PL/SQL block. The
pl/sql does not compiles and gives me the following address
SQL> DECLARE
2 CURSOR c_my IS
3 SELECT deptno, hiredate, record_id
4 FROM (SELECT deptno, ename, hiredate, ROW_NUMBER()
5 OVER (ORDER BY hiredate) AS record_id
6 FROM emp)
7 WHERE record_id >= 2
8 AND record_id <=5;
9 BEGIN
10 FOR c_rec IN c_my LOOP
11 dbms_output.put_line(c_rec.ename);
12 END LOOP;
13 END;
14 /
OVER (ORDER BY hiredate) AS record_id
ERROR at line 5:
ORA-06550: line 5, column 13:
PLS-00103: Encountered the symbol "(" when expecting one of the
following:
, from
Question: Can you please tell me how I can use the ROW_NUMBER()
function in PL/SQL. I need to use this for selecting the correct
range of records for Pagination on a website.
Thanks in advance
Prashant

Answer 1

As Andrew said, PL/SQL hasn't caught up with the newer bits of
SQL.  I have heard that in 9i, they will be the same, but in 8i
there are still things that you can do in SQL that you cannot do
directly in PL/SQL, such as the new functions like ROW_NUMBER. 
However, you can use NDS as a work around.  The following does
the same as what you posted:
SET SERVEROUTPUT ON
DECLARE
  TYPE c_my_type  IS REF CURSOR;
  c_my               c_my_type;
  TYPE c_rec_type IS RECORD
    (deptno          emp.deptno%TYPE,
     ename           emp.ename%TYPE,
     hiredate        emp.hiredate%TYPE,
     record_id       INTEGER);
  c_rec              c_rec_type;
  v_sql              VARCHAR2 (4000);
BEGIN
  v_sql :=
  'SELECT deptno, ename, hiredate, record_id
   FROM   (SELECT deptno, ename, hiredate,
                  ROW_NUMBER() OVER
                    (ORDER BY hiredate)
                    AS record_id
          FROM    emp)
   WHERE  record_id >= 2
   AND    record_id <= 5';
  OPEN c_my FOR v_sql;
  LOOP
    FETCH c_my INTO c_rec;
    EXIT WHEN c_my%NOTFOUND;
    DBMS_OUTPUT.PUT_LINE (c_rec.ename);
  END LOOP;
END;
However, you stated that you need it for selecting the correct
range of records for pagination on a website.  For that, you
will want something more like this:
CREATE OR REPLACE PACKAGE package_name
AS
  TYPE c_my_type     IS     REF cursor;
  PROCEDURE procedure_name
    (c_my            IN OUT c_my_type,
     p_record_id1    IN     NUMBER DEFAULT 1,
     p_record_id2    IN     NUMBER DEFAULT 4);
END package_name;
CREATE OR REPLACE PACKAGE BODY package_name
AS
  PROCEDURE procedure_name
    (c_my            IN OUT c_my_type,
     p_record_id1    IN     NUMBER DEFAULT 1,
     p_record_id2    IN     NUMBER DEFAULT 4)
  IS
    v_sql                   VARCHAR2 (4000);
  BEGIN
    v_sql :=
        'SELECT deptno, ename, hiredate, record_id'
    || ' FROM   (SELECT deptno, ename, hiredate,'
    ||                ' ROW_NUMBER() OVER'
    ||                  ' (ORDER BY hiredate)'
    ||                  ' AS record_id'
    || ' FROM    emp)'
    || ' WHERE  record_id >= :a'
    || ' AND    record_id <= :b';
    OPEN c_my FOR v_sql
    USING p_record_id1, p_record_id2;   
  END procedure_name;
END package_name;