Count ALL rows in databases

Question

Hi experts!
I need the total number of ROWS in EACH database i have (All schema)
I've tried this for each DB
select sum(num_rows)
from sys.dba_tables
where owner like '%%'
i obtain the number of all rows for all schema in database.
I have many database, i use agent g10.0 and enterprice manager to query them.
I
've seen that in Enterprise Manager, when you select a Database Istance, then go on "administration" tab, and u click on TABLES link, you can see number of rows and last time the table was analyzed. How are they have been calculated? With table dba_tables? How can i query to obtain these values?
I know it's a stupid task but my boss wants this info :(

Answer 1

> I know it's a stupid task but my boss wants this info :(
Tell him two gazillion. Also tell him that the gazillion scale has been specifically created for managers like him with heads firmly stuck up the back side.
Anyway, here's some sample code. Note that you cannot use DBA_TABLES view. Object tables are not listed in there and they can contain rows (obviously). There is also the case of dealing with case and "weirdly" names tables - thus double quotes are needed.
I only did the first 10 tables.. It is stupid to just one, never mind all of them in database...
SQL> declare
2 type TStrings is table of varchar2(1000);
3
4 cursor c is
5 select '"'||owner||'"."'||object_name||'"' as TAB_NAME from dba_objects where object_type='TABLE' and rownum < 11 order by 1;
6
7 tabList TStrings;
8 sqlSelect varchar2(1000);
9 cnt integer;
10 total integer;
11
12 procedure W( line varchar2 ) is
13 begin
14 DBMS_OUTPUT.put_line( line );
15 end;
16 begin
17 total := 0;
18 open c;
19 loop
20 fetch c bulk collect into tabList limit 100;
21 for i in 1..tabList.Count
22 loop
23 sqlSelect := 'select count(*) from '||tabList(i);
24 begin
25 execute immediate sqlSelect into cnt;
26 total := total + cnt;
27 W( sqlSelect || ' ' || cnt || ' rows(s)' );
28 exception when OTHERS then
29 W( sqlSelect || ' ' || sqlerrm(sqlcode) );
30 end;
31 end loop;
32 exit when c%NOTFOUND;
33 end loop;
34 close c;
35 W( total|| ' gazillion rows in the database' );
36 end;
37 /
select count(*) from "SYS"."CLU$" 10 rows(s)
select count(*) from "SYS"."COL$" 43696 rows(s)
select count(*) from "SYS"."CON$" 2898 rows(s)
select count(*) from "SYS"."FILE$" 5 rows(s)
select count(*) from "SYS"."ICOL$" 2184 rows(s)
select count(*) from "SYS"."IND$" 1434 rows(s)
select count(*) from "SYS"."PROXY_ROLE_DATA$" 0 rows(s)
select count(*) from "SYS"."SEG$" 3032 rows(s)
select count(*) from "SYS"."UET$" 0 rows(s)
select count(*) from "SYS"."UNDO$" 11 rows(s)
53270 gazillion rows in the database
PL/SQL procedure successfully completed.
SQL> PS. Cursor needs fine tuning as certain table objects cannot be directly accessed via a SELECT statement (e.g. nested tables, overflow IOT tables, etc).