Pages Templates still reset currency...

Question

Is there anybody who is struggling with this as well?
I thought this would be a really obvious bug and they's fix it in 09, but nothing.
Whenever I create a Pages Template with a currency other than British Pounds and save it, after opening it is reset to Pounds - it's a simple and obvious bug and I wrot eto Apple as well, so they should be aware of it, but nothing happens - am I the only one here?
Cheers - Christoph

Answer 1

Hi Fruhulda
If you insert a table in a Pages document (same behavior with Numbers) and set a cell as currency one using $ if your system's setting is €,
if you save the document as a template, the documents created from this custom template will contain a currency matching your system's setting.
It's really odd.
I wish to know if the OP used the Feedback link or if he reported to the BugReporter area.
There is a quick and dirty workaround.
Don't save as a template but as a standard document and create new documents with this script.
--[SCRIPT openFakeTemplate]
Enregistrer le script en tant que Script ou Progiciel : openFakeTemplate.xxx
Sous 10.6 un progiciel se nomme Application.
Si c'est un Script, déplacer le fichier créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:
Il vous faudra peut-être créer le dossier Applications.
menu Scripts > openFakeTemplate
Si c'est un Progiciel, laissez le sur le bureau pour y glisser l'icône d'un pseudo_modèle Numbers ou Pages.
Dans les deux cas, un clône du pseudo_modèle sera ouvert avec un nom horodaté.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as Script or Application Bundle: openFakeTemplate.xxx
Under 10.6, Application Bundle is named Application.
If you saved as Script, movethe newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:
Maybe you would have to create the folder Applications by yourself.
Go to menu Scripts > openFakeTemplate
If you saved as Application (bundle), leave it on the Desktop so you will be able to drag & drop on its icon a fakeTemplate's one.
In both cases, a dateTime stamped clone of the fakeTemplate will be open.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox
--=====
Yvan KOENIG (VALLAURIS, France)
2009/09/29
property permitted4 : {"com.apple.iwork.pages.sffpages", "com.apple.iwork.numbers.sffnumbers"}
property permitted5 : {"com.apple.iwork.pages.pages", "com.apple.iwork.numbers.numbers"}
property permitted : permitted5 & permitted4
--=====
on run (*
lignes exécutées si on double clique sur l'icône du script application
• lines executed if one double click the application script's icon *)
tell application "System Events"
if my parleAnglais() then
set myPrompt to "Choose an iWork’s document"
else
set myPrompt to "Choisir un document iWork"
end if -- parleAnglais
if 5 > (system attribute "sys2") then (*
if Mac Os X 10.4.x *)
set allowed to my permitted
else (*
it's Mac OS X 10.5.x with a bug with Choose File *)
set allowed to {}
end if -- 5 > (system…
my commun(choose file with prompt myPrompt of type allowed without invisibles) (* un alias *)
end tell
end run
--=====
on open (sel) (*
sel contient une liste d'alias des élémentsqu'on a déposés sur l'icône du script (la sélection)
• sel contains a list of aliases of the items dropped on the script's icon (the selection) *)
my commun(item 1 of sel) (* an alias *)
end open
--=====
on commun(source)
tell application "System Events" to tell disk item (source as text)
set typeID to (type identifier) as text
set nomSource to name
set ext to name extension
end tell
if typeID is not in my permitted then
if my parleAnglais() then
error "“" & (source as text) & "” is not a Numbers or Pages document!"
else
error "«" & (source as text) & "» n’est pas un document Numbers ou Pages !"
end if -- my parleAnglais()
end if -- typeID
set nomCourt to text 1 thru -(2 + (length of ext)) of nomSource
set nouveauNom to nomCourt & my dateTimeStamp() & "." & ext
tell application "Finder"
set dupli to (duplicate source) as alias
set name of dupli to nouveauNom
set dupli to dupli as alias
open dupli
end tell
end commun
--=====
on dateTimeStamp()
return (do shell script "date +_%Y%m%d-%H%M%S")
end dateTimeStamp
--=====
on parleAnglais()
local z
try
tell application "Pages" to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
-- [/SCRIPT]
Yvan KOENIG (VALLAURIS, France) mardi 29 septembre 2009 18:46:11