RSPC Variant does not exist - Could not find or load print parameters

Question

We are on BI 7.0 (support pack SAPKW70017).  We recently freshed test system from production.   After the refresh, we have problems opening all the process chains.  
1. When I go to RSPC to open a process chain, I get many messages like this:
Variant &0000000067180 does not exist (there are different variant numbers)
Message no. DB612
Diagnosis
You selected variant &0000000067180 for program RSPROCESS.
This variant does not exist.
2. When I go to SM21 to check the system log, it displays many entries like below:
EJ  F Could not find or load print parameters for step 1, job BI_PROCESS_TRIGGER/09134500
Documentation for system log message EJ F :                                                                               
An error occurred during loading of the print parameters for a        
background job step.                                                  
The print parameter record may have been deleted even though there was
a still a step that needed that data. This is an error as the         
reorganization of the print parameters should prevent this from       
happening.                                                            
To fix the problem, edit the step and save it, copy the job, or       
schedule a new job. The print parameters will be regenerated in all   
these cases.    
3. I applied the OSS note 1169659 - Correction: Process variants not entered by BDLS.   The Basis rerun BDLS.  But it did not fix the problem.
Would appreciate if someone could provide any help.
Thank you.

Answer 1

Hi Rebecca.
1) Please verify if exist process types called 'unknown job'. If exist:  delete process types called 'unknown job' in your process chain. To do that please remove the chain from scheduling (menu bar > process chain > remove from schedule), afterwards switch the detail view on (menu bar >  view) > right mouse click on the process type "unknown job" > displaying scheduled jobs > delete that job. After deletion of the 'unknown jobs' activate and schedule your process chain again.
2) After the removal of the 'unknown jobs' please check if the error messages with the missing variants pop up when calling your process chain disappears. If not, please implement and execute the attached report Z_FIND_JOBS_WITHOUT_VARIANT which deletes the jobs without variants.
I have already attached report as Report Z_FIND_JOBS_WITHOUT_VARIANT, you can download and create the report accordingly.
= = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
REPORT  Z_FIND_JOBS_WITHOUT_VARIANT.
data: l_t_job type table of tbtcp with header line,
      l_s_varsel    TYPE rsvar,
      l_t_variant   TYPE TABLE OF rsparams.
parameters: delete type rs_bool.
select * from tbtcp as job into table l_t_job
                    where progname = 'RSPROCESS'
                    and   exists ( select * from tbtco
                          where jobname = job~jobname
                          and   jobcount = job~jobcount
                          and   status = 'S' ).
loop at l_t_job.
  l_s_varsel-report  = l_t_job-progname.
  l_s_varsel-variant = l_t_job-variant.
  CALL FUNCTION 'RS_VARIANT_CONTENTS'
    EXPORTING
      report               = l_s_varsel-report
      variant              = l_s_varsel-variant
      execute_direct       = 'X'
    TABLES
      valutab              = l_t_variant
    EXCEPTIONS
      variant_non_existent = 1
      variant_obsolete     = 2
      OTHERS               = 3.
  if sy-subrc <> 0.
    write: / l_t_job-jobname, l_t_job-jobcount.
    if delete = 'X'.
      CALL FUNCTION 'BP_JOB_DELETE'
        EXPORTING
          JOBCOUNT = l_t_job-jobcount
          JOBNAME  = l_t_job-jobname
        EXCEPTIONS
          OTHERS   = 1.
      IF SY-SUBRC <> 0.
        write 'not deleted'.
      else.
        write 'successfully deleted'.
      ENDIF.
    endif.
  endif.
endloop.
= = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
I hope I can be helpful.
Thanks,
Walter Oliveira.