Tell block ends prematurely

Question

Hi,
I'm trying to use Image Events to scale an image within an AppleScript I wrote. As a stand alone app, using only Image Events (IE), copying the script from one of the examples, all works fine. When I put that example script into mine as a subroutine, it doesn't work. The tell block that it's in ends, and the finder takes over.
my callling routine:
... setup stuff
tell application "Finder"
if not (exists folder "image gallery" of base_folder) then make new folder at base_folder with properties {name:"image gallery"}
set the_files to every file of base_folder
repeat with each_file in the_files
if the name extension of each_file is "jpg" then
my scaleImage800(duplicate each_file to (folder "image gallery" of folder base_folder))
end if
end repeat
end tell
my subroutine:
on scaleImage800(the_file)
try
tell application "Image Events"
launch
-- open the image file
set this_image to open the_file
-- perform action
scale this_image to size 800
-- save the changes
save this_image with icon
-- purge the open image data
close this_image
end tell
on error msg
display dialog msg
end try
end scaleImage600
and the results:
end tell
tell application "Image Events"
launch
current application
------ here's the problem
end tell
tell application "Finder"
------ where does this come from?
open document file "Fishing.jpg" of folder "image gallery" of folder "rmearns" of folder "Submitted Images" of folder "Camera Roch site template" of folder "IE downloads" of folder "Downloads" of folder "benbarlo" of folder "Users" of startup disk
end tell
tell current application
display dialog "The variable this_image is not defined."
"User canceled."
For some reason, the "tell application "Image Events"" statement doesn't "hold". AS does an "end tell" and "tell application "finder"" on its own right after, which causes the "open" statement to be executed by finder, not IE.
What's happening?
Thanks,
Ben
macbook 13, DP Quicksilver   Mac OS X (10.4.9)   Macbook 512MB, QS 1.5GB
macbook 13, DP Quicksilver   Mac OS X (10.4.9)   Macbook 512MB, QS 1.5GB
macbook 13, DP Quicksilver   Mac OS X (10.4.9)   Macbook 512MB, QS 1.5GB

Answer 1

property images_folder : "image gallery" -- User definded folder.
property originals_folder : "_originals" -- Location of duplicated files.
property processed_folder : "_processed" -- Location of resized files.
tell application "Finder" -- Required for 'path to', 'exists', 'every file of', and 'name extension' commands.
set base_folder to (path to desktop folder from user domain) as string -- Hardwired location of 'images_folder'.
if (exists folder (base_folder & images_folder)) then -- Determine if 'images_folder' exists. If so, continue ...
set the_files to every file of folder (base_folder & images_folder) -- Obtain full path of each file in 'images_folder'.
-- Determine if 'originals_folder' exists. If not, create it.
if (not (exists folder (base_folder & images_folder & ":" & originals_folder))) then make new folder at folder (base_folder & images_folder) with properties {name:originals_folder}
-- Determine if 'processed_folder' exists. If not, create it.
if (not (exists folder (base_folder & images_folder & ":" & processed_folder))) then make new folder at folder (base_folder & images_folder) with properties {name:processed_folder}
repeat with each_file in the_files -- Cycle throught the list of obtained files.
duplicate each_file to folder (base_folder & images_folder & ":" & originals_folder) with replacing -- Store a master copy, in 'originals_folder'.
if ((name extension of each_file) is "jpg") then my scaleImage800(each_file as string) -- Process only '.jpg' files.
move each_file to folder (base_folder & images_folder & ":" & processed_folder) with replacing -- Store the processed copy, in 'processed_folder'.
end repeat
else -- ... otherwise, create a new 'images_folder' at 'base_folder'.
make new folder at folder base_folder with properties {name:images_folder} -- Create new 'images_folder' folder.
display dialog "A new (empty) folder, titled '" & images_folder & "' has been created on the 'Desktop." buttons {"OK"} default button "OK"
end if
end tell
try -- Optional code.
tell application "Image Events" to quit -- Quit 'Image Events'.
end try
try -- Optional code.
tell application "Image Capture Extension" to quit -- Quit 'Image Capture Extension.
end try
on scaleImage800(the_file)
try
tell application "Image Events" -- Required fo 'open', 'scale to', 'save with', and 'close' commands.
launch
set fRef to open the_file -- Open the image file
scale fRef to size 800 -- Scale the image
save fRef with icon -- Save the image
close fRef -- Close the image
end tell
on error msg
display dialog msg -- Handle any errors.
end try
end scaleImage800
  Mac OS X (10.4.6)