VBA - Setting Custom Fields For Sub-Projects Using a Master File

Question

Hello,
I was wondering if anyone had any experience or could provide some help with a Macro to set the Custom Fields in Sub-Project Files directly from the Macro. I had this macro working in the past with Project 2007, but it has been a couple years and I am struggling
to resolve an error. I am currently running Project 2010 with SP2. I intend to use this Macro in our Server 2010 environment, however at this time, I'm testing locally on my desktop.
Scenario.
I have a Master File with 2 sub-project (Project A, and Project B) inserted. While working in the Master File, I create a custom field title "TEAM Lookup". While in the Master File and without having to individually go and open, edit, save, and
close each sub-project, push the custom field down to the project files.
ERROR: Currently, the Macro will run and I can step through the lines of code until line 12 where I'm asking Project to use the organizer to shift the newly created custom field from the Master File to a sub-project. The line appears to
populate correctly, but instead of continuing through the loop, an error is caught (ID - 1101 - "The File (Master File) was not found")
Any ideas or suggestions would be greatly appreciated. Thanks
Sample Code
1. Sub CopyCustomFieldToSubprojects()
2. Dim MASTER, custfield, contin, AllDone
3. Dim SubProj As Subproject
4. Alerts False
5. MASTER = ActiveProject.Name
6. Application.EnableCancelKey = pjInterrupt
7. custfield = CustomFieldGetName(ActiveCell.FieldID) & ActiveCell.FieldName
8. On Error GoTo errhand
9. contin = MsgBox("This macro will copy the field " & "(" & custfield & ")" & " (the currently selected field) to all subprojects in this consolidated schedule." & vbCrLf & vbCrLf & "Be
patient, it may take more than 70 seconds to run. You will be notified when it's done. Continue?", vbOKCancel)
10.    If contin = vbCancel Then GoTo done
11.    For Each SubProj In ActiveProject.Subprojects
12.    OrganizerMoveItem Type:=pjFields, FileName:=MASTER, ToFileName:=SubProj.SourceProject.Name, Name:=custfield
13.    Next SubProj
14.     AllDone = MsgBox("The " & custfield & " field has been copied to all subprojects.", vbOKOnly)
15. GoTo done
16. errhand:
17. ret = err.Description
18. ret1 = err.Number
19. done:
20. End Sub

Answer 1

SGBlaine,
Project VBA can get rather fussy about some things so you just have to find out what it wants and then adjust your code accordingly. The following will work:
Note the tweaks to the custfield variable and to the MASTER and source project names. Also when working with strings in VBA it is a good idea to eliminate at least one little gotcha, the need for exact capitalization. Therefore I always add the Option Compare
Text statement. In your macro it won't make any difference since you do not directly create a string value, but it's good practice to have the option.
Option Compare Text
Sub CopyCustomFieldToSubprojects()
Dim MASTER, custfield, contin, AllDone
Dim SubProj As Subproject
Alerts False
MASTER = ActiveProject.FullName 'FullName includes the path, now it can find it
Application.EnableCancelKey = pjInterrupt
custfield = CustomFieldGetName(ActiveCell.FieldID) & " (" & ActiveCell.FieldName & ")"
'strings are very fussy, it has to be exact
On Error GoTo errhand
contin = MsgBox("This macro will copy the field " & "(" & custfield & ")" & " (the currently selected field) to all subprojects in this consolidated schedule." & vbCrLf & vbCrLf & "Be
patient, it may take more than 70 seconds to run. You will be notified when it's done. Continue?", vbOKCancel)
If contin = vbCancel Then GoTo done
For Each SubProj In ActiveProject.Subprojects
    OrganizerMoveItem Type:=pjFields, FileName:=MASTER, ToFileName:=SubProj.SourceProject.FullName, Name:=custfield
Next SubProj
AllDone = MsgBox("The " & custfield & " field has been copied to all subprojects.", vbOKOnly)
GoTo done
errhand:
ret = Err.Description
ret1 = Err.Number
done:
End Sub
John